mirror of
git://git.yoctoproject.org/meta-intel
synced 2026-01-01 13:58:05 +00:00
c7b6895705
CVE_CHECK_IGNORE was deprecated and shouldn't be used anymore. Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
44 lines
1.4 KiB
BlitzBasic
44 lines
1.4 KiB
BlitzBasic
SUMMARY="ixgbe kernel driver for Intel Magnolia Park 10GbE"
|
|
DESCRIPTION="The ixgbe driver supports 82598- and 82599-based \
|
|
PCI Express* 10 Gigabit Network Connections."
|
|
|
|
HOMEPAGE = "https://sourceforge.net/projects/e1000/"
|
|
SECTION = "kernel/network"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://${WORKDIR}/${BP}/COPYING;md5=a216b4192dc6b777b6f0db560e9a8417"
|
|
|
|
SRC_URI = "https://sourceforge.net/projects/e1000/files/ixgbe%20stable/${PV}/${BP}.tar.gz \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "a844f1fea8064e30b276792455c3b286c1d7af26731e8f865d4a4e9ed1dcf4ab"
|
|
|
|
UPSTREAM_CHECK_URI = "https://sourceforge.net/projects/e1000/files/ixgbe%20stable/"
|
|
UPSTREAM_CHECK_REGEX = "ixgbe%20stable/(?P<pver>\d+(\.\d+)+)/"
|
|
|
|
CVE_PRODUCT = "linux:linux_kernel_ixgbe"
|
|
|
|
S = "${WORKDIR}/${BP}/src"
|
|
|
|
EXTRA_OEMAKE=' KSRC="${STAGING_KERNEL_DIR}" KOBJ="${STAGING_KERNEL_BUILDDIR}" KVER="${KERNEL_VERSION}" INSTALL_MOD_PATH="${D}"'
|
|
|
|
KERNEL_MODULE_AUTOLOAD:append:intel-core2-32 = " ixgbe"
|
|
KERNEL_MODULE_AUTOLOAD:append:intel-corei7-64 = " ixgbe"
|
|
|
|
inherit module
|
|
|
|
do_install:append () {
|
|
# Install scripts/set_irq_affinity
|
|
install -d ${D}${sysconfdir}/network
|
|
install -m 0755 ${S}/../scripts/set_irq_affinity ${D}${sysconfdir}/network
|
|
|
|
rm -rf ${D}${prefix}/man
|
|
}
|
|
|
|
PACKAGES += "${PN}-script"
|
|
|
|
FILES:${PN}-script += "${sysconfdir}/network/set_irq_affinity"
|
|
|
|
EXCLUDE_FROM_WORLD = "1"
|
|
|
|
CVE_STATUS[CVE-2015-1142857] = "fixed-version: Fixed from version 4.4-rc1"
|