mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
ibus: initial add 1.5.21
It is a depency for gnome-shell Signed-off-by: Andreas Müller <schnitzeltony@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
This commit is contained in:
Andreas Müller
Khem Raj
parent
9429dba394
commit
39d717de36
34
meta-gnome/recipes-support/ibus/ibus-native.bb
Normal file
34
meta-gnome/recipes-support/ibus/ibus-native.bb
Normal file
|
|
@ -0,0 +1,34 @@
|
|||
require ${BPN}.inc
|
||||
|
||||
inherit native
|
||||
|
||||
DEPENDS += " \
|
||||
glib-2.0-native \
|
||||
dbus-native \
|
||||
iso-codes \
|
||||
"
|
||||
|
||||
PACKAGECONFIG = ""
|
||||
|
||||
# for allarch iso-codes
|
||||
EXTRA_NATIVE_PKGCONFIG_PATH = ":${RECIPE_SYSROOT}${datadir_native}/pkgconfig"
|
||||
# for allarch unicode-ucd - just to make configure happy
|
||||
EXTRA_OECONF += "--with-ucd-dir=${RECIPE_SYSROOT}${datadir_native}/unicode/ucd"
|
||||
|
||||
do_compile() {
|
||||
cd src
|
||||
# seems by moving to src we break dependency tracking so build what's
|
||||
# necessary step by step
|
||||
oe_runmake ibusenumtypes.h
|
||||
oe_runmake ibusmarshalers.h
|
||||
oe_runmake ibusenumtypes.c
|
||||
oe_runmake unicode-parser
|
||||
}
|
||||
|
||||
do_install() {
|
||||
install -d ${D}/${libdir}
|
||||
install -m 755 ${S}/src/.libs/libibus-*.so* ${D}/${libdir}
|
||||
|
||||
install -d ${D}/${bindir}
|
||||
install -m 755 ${S}/src/.libs/unicode-parser ${D}/${bindir}
|
||||
}
|
||||
37
meta-gnome/recipes-support/ibus/ibus.bb
Normal file
37
meta-gnome/recipes-support/ibus/ibus.bb
Normal file
|
|
@ -0,0 +1,37 @@
|
|||
require ${BPN}.inc
|
||||
|
||||
DEPENDS += " \
|
||||
${BPN}-native \
|
||||
glib-2.0-native \
|
||||
glib-2.0 \
|
||||
dbus \
|
||||
iso-codes \
|
||||
"
|
||||
|
||||
inherit gtk-icon-cache bash-completion
|
||||
|
||||
# for unicode-ucd
|
||||
EXTRA_OECONF += "--with-ucd-dir=${STAGING_DATADIR}/unicode/ucd"
|
||||
|
||||
PACKAGECONFIG ??= " \
|
||||
dconf vala \
|
||||
${@bb.utils.contains_any('DISTRO_FEATURES', [ 'wayland', 'x11' ], 'gtk3', '', d)} \
|
||||
${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11', d)} \
|
||||
"
|
||||
|
||||
do_configure_prepend() {
|
||||
# run native unicode-parser
|
||||
sed -i 's:$(builddir)/unicode-parser:unicode-parser:g' ${S}/src/Makefile.am
|
||||
}
|
||||
|
||||
FILES_${PN} += " \
|
||||
${datadir}/dbus-1 \
|
||||
${datadir}/GConf \
|
||||
${datadir}/glib-2.0 \
|
||||
${libdir}/gtk-3.0 \
|
||||
"
|
||||
|
||||
FILES_${PN}-dev += " \
|
||||
${datadir}/gettext \
|
||||
"
|
||||
|
||||
36
meta-gnome/recipes-support/ibus/ibus.inc
Normal file
36
meta-gnome/recipes-support/ibus/ibus.inc
Normal file
|
|
@ -0,0 +1,36 @@
|
|||
SUMMARY = "Intelligent Input Bus for Linux/Unix"
|
||||
HOMEPAGE = "https://github.com/ibus/ibus/wiki"
|
||||
LICENSE = "LGPLv2.1"
|
||||
LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
|
||||
|
||||
inherit autotools-brokensep pkgconfig gobject-introspection gettext gtk-doc vala
|
||||
|
||||
PV = "1.5.21"
|
||||
|
||||
DEPENDS = "unicode-ucd"
|
||||
|
||||
SRC_URI = " \
|
||||
git://github.com/ibus/ibus.git \
|
||||
file://0001-Do-not-try-to-start-dbus-we-do-not-have-dbus-lauch.patch \
|
||||
"
|
||||
SRCREV = "ae0040c73466bb6e78fce5e669a55fcce6ffd16d"
|
||||
S = "${WORKDIR}/git"
|
||||
|
||||
PACKAGECONFIG[appindicator] = "--enable-appindicator,--disable-appindicator,qtbase"
|
||||
PACKAGECONFIG[dconf] = "--enable-dconf,--disable-dconf,dconf"
|
||||
PACKAGECONFIG[gtk2] = "--enable-gtk2,--disable-gtk2,gtk+"
|
||||
PACKAGECONFIG[gtk3] = "--enable-gtk3,--disable-gtk3,gtk+3"
|
||||
PACKAGECONFIG[wayland] = "--enable-wayland,--disable-wayland,wayland"
|
||||
PACKAGECONFIG[vala] = "--enable-vala,--disable-vala"
|
||||
PACKAGECONFIG[x11] = "--enable-xim --enable-ui,--disable-xim --disable-ui,virtual/libx11"
|
||||
|
||||
EXTRA_OECONF = " \
|
||||
--disable-tests \
|
||||
--disable-emoji-dict \
|
||||
--disable-python2 \
|
||||
"
|
||||
|
||||
do_configure_prepend() {
|
||||
touch ${S}/ChangeLog
|
||||
touch ${S}/ABOUT-NLS
|
||||
}
|
||||
|
|
@ -0,0 +1,39 @@
|
|||
From f567bcbc2108d722faa90afeb03d3a3bcdf5f58b Mon Sep 17 00:00:00 2001
|
||||
From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
|
||||
Date: Fri, 10 May 2019 14:30:08 +0200
|
||||
Subject: [PATCH] Do not try to start dbus - we do not have dbus-lauch
|
||||
MIME-Version: 1.0
|
||||
Content-Type: text/plain; charset=UTF-8
|
||||
Content-Transfer-Encoding: 8bit
|
||||
|
||||
Upstream-Status: Inappropriate [OE specific]
|
||||
|
||||
Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
|
||||
---
|
||||
data/dconf/make-dconf-override-db.sh | 6 ------
|
||||
1 file changed, 6 deletions(-)
|
||||
|
||||
diff --git a/data/dconf/make-dconf-override-db.sh b/data/dconf/make-dconf-override-db.sh
|
||||
index 9c650e97..02fbf059 100755
|
||||
--- a/data/dconf/make-dconf-override-db.sh
|
||||
+++ b/data/dconf/make-dconf-override-db.sh
|
||||
@@ -12,10 +12,6 @@ export XDG_CACHE_HOME="$TMPDIR/cache"
|
||||
export GSETTINGS_SCHEMA_DIR="$TMPDIR/schemas"
|
||||
mkdir -p $XDG_CONFIG_HOME $XDG_CACHE_HOME $GSETTINGS_SCHEMA_DIR
|
||||
|
||||
-eval `dbus-launch --sh-syntax`
|
||||
-
|
||||
-trap 'rm -rf $TMPDIR; kill $DBUS_SESSION_BUS_PID' ERR
|
||||
-
|
||||
# in case that schema is not installed on the system
|
||||
glib-compile-schemas --targetdir "$GSETTINGS_SCHEMA_DIR" "$PWD"
|
||||
|
||||
@@ -46,5 +42,3 @@ for schema in $schemas; do
|
||||
done
|
||||
|
||||
rm -rf $TMPDIR
|
||||
-
|
||||
-kill $DBUS_SESSION_BUS_PID
|
||||
--
|
||||
2.20.1
|
||||
|
||||
Loading…
Reference in New Issue
Block a user