mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
fc78d37ff0
Please see https://git.yoctoproject.org/poky/commit/?id=4dd321f8b83afecd962393101b2a6861275b5265 for what changes are needed, and sed commands that can be used to make them en masse. I've verified that bitbake -c patch world works with these, but did not run a world build; the majority of recipes shouldn't need further fixups, but if there are some that still fall out, they can be fixed in followups. Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
41 lines
1.6 KiB
BlitzBasic
41 lines
1.6 KiB
BlitzBasic
SUMMARY = "A high-performance REST toolkit written in C++"
|
|
HOMEPAGE = "https://pistacheio.github.io/pistache"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=fa818a259cbed7ce8bc2a22d35a464fc"
|
|
|
|
SRC_URI = "git://github.com/pistacheio/pistache.git;branch=master;protocol=https"
|
|
# SRCREV tagged 0.4.26
|
|
SRCREV = "ddffda861aa49012dcda28f1362d0339e718cd52"
|
|
|
|
|
|
DEPENDS = "rapidjson"
|
|
|
|
inherit pkgconfig meson
|
|
|
|
PACKAGECONFIG ?= "openssl brotli deflate zstd examples"
|
|
PACKAGECONFIG[openssl] = "-DPISTACHE_USE_SSL=true, -DPISTACHE_USE_SSL=false, openssl"
|
|
PACKAGECONFIG[brotli] = "-DPISTACHE_USE_CONTENT_ENCODING_BROTLI=true, -DPISTACHE_USE_CONTENT_ENCODING_BROTLI=false, brotli"
|
|
PACKAGECONFIG[deflate] = "-DPISTACHE_USE_CONTENT_ENCODING_DEFLATE=true, -DPISTACHE_USE_CONTENT_ENCODING_DEFLATE=false, zlib"
|
|
PACKAGECONFIG[zstd] = "-DPISTACHE_USE_CONTENT_ENCODING_ZSTD=true, -DPISTACHE_USE_CONTENT_ENCODING_ZSTD=false, zstd"
|
|
PACKAGECONFIG[examples] = "-DPISTACHE_BUILD_EXAMPLES=true, -DPISTACHE_BUILD_EXAMPLES=false"
|
|
PACKAGECONFIG[test] = "-DPISTACHE_BUILD_TESTS=true, -DPISTACHE_BUILD_TESTS=false, gtest curl"
|
|
|
|
do_install:append () {
|
|
if ${@bb.utils.contains("PACKAGECONFIG", "examples", "true", "false", d)}; then
|
|
install -d ${D}${bindir}
|
|
rm -rf ${B}/examples/*.p/
|
|
install -m 0755 ${B}/examples/run* ${D}${bindir}/
|
|
fi
|
|
}
|
|
|
|
PACKAGES += "${PN}-examples"
|
|
FILES:${PN}:remove = " ${bindir}/*"
|
|
RDEPENDS:${PN}-examples += "${PN}"
|
|
FILES:${PN}-examples = "${bindir}"
|
|
|
|
RDEPENDS:${PN} += "rapidjson"
|
|
|
|
COMPATIBLE_HOST:libc-musl = "null"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|