mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
3564ff8f30
ChangeLog:
2024-12-19 (bug) [844c0b] Menu entry underline does not consider
activeborderwidth
2025-01-03 (bug) [13ac26] wm iconbitmap does not correctly set the
icon pixmap hint on macOS
2025-01-27 (bug) [080a28] Aqua: tk_getOpenFile crash
2025-01-28 (bug) [c99266] console menu zh_cn translations
2025-03-17 (bug) [159aa5] MS-Win: Incorrect system menu entries for
transient toplevels
2025-03-17 (bug) [91d0e9] MS-Win: Withdrawn Tk transient windows can
reappear in Windows taskbar preview
2025-04-26 (bug) [111f66] Aqua: cannot iconify all windows
2025-05-17 (bug) [7231bf99] Setting ttk state may change the variable
passed by value
2025-05-29 (feature) [17b509] Win: support PNG images in icon files.
2025-06-01 (bug) [5d0bc3] block cursor size on a tab is too large
2025-07-03 (bug) [6b0f77] gcc 14 breaks configure test for bigendian
leading to broken floating point
2025-07-14 (bug) [d25b72] error popup on ttk::scale with invisible
trough
2025-07-16 (bug) [770fa0] loading windows dll's in Cygwin doesn't
work with high-entropy-va
2025-07-25 (bug) [3d13f8,e90e8c] Aqua: dark mode improvements
2025-07-25 (bug) [e94c8b] interop with clipboard managers
2025-08-11 (bug) [dc38c9] Aqua: NSHighResolutionCapable should be a
Boolean value
2025-08-11 (bug) [4e1e10] Aqua: CGRect/NSRect type mismatch on 32-bit
Signed-off-by: Yi Zhao <yi.zhao@windriver.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
104 lines
3.2 KiB
BlitzBasic
104 lines
3.2 KiB
BlitzBasic
SUMMARY = "Tool Command Language ToolKit Extension"
|
|
HOMEPAGE = "http://tcl.sourceforge.net"
|
|
SECTION = "devel/tcltk"
|
|
|
|
# http://www.tcl.tk/software/tcltk/license.html
|
|
LICENSE = "TCL"
|
|
LIC_FILES_CHKSUM = "file://license.terms;md5=c88f99decec11afa967ad33d314f87fe \
|
|
file://compat/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
|
|
file://doc/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
|
|
file://library/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
|
|
file://macosx/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
|
|
file://tests/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
|
|
file://unix/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
|
|
file://win/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
|
|
file://xlib/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
|
|
"
|
|
|
|
DEPENDS = "tcl8 virtual/libx11 libxt"
|
|
|
|
SRC_URI = "\
|
|
${SOURCEFORGE_MIRROR}/tcl/tk${PV}-src.tar.gz \
|
|
file://confsearch.diff \
|
|
file://tkprivate.diff \
|
|
file://fix-xft.diff \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "e4982df6f969c08bf9dd858a6891059b4a3f50dc6c87c10abadbbe2fc4838946"
|
|
|
|
UPSTREAM_CHECK_URI = "https://sourceforge.net/projects/tcl/files/Tcl/"
|
|
UPSTREAM_CHECK_REGEX = "Tcl/(?P<pver>\d+(\.\d+)+)/"
|
|
|
|
S = "${UNPACKDIR}/tk${PV}"
|
|
|
|
# Short version format: "8.6"
|
|
VER = "${@os.path.splitext(d.getVar('PV'))[0]}"
|
|
|
|
LDFLAGS += "-Wl,-rpath,${libdir}/tcltk/${PV}/lib"
|
|
CFLAGS += "-I${STAGING_INCDIR}/tcl${VER}"
|
|
inherit autotools features_check pkgconfig
|
|
|
|
AUTOTOOLS_SCRIPT_PATH = "${S}/unix"
|
|
EXTRA_AUTORECONF += "--exclude=aclocal"
|
|
|
|
# depends on virtual/libx11
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
EXTRA_OECONF = "\
|
|
--enable-threads \
|
|
--with-x \
|
|
--with-tcl=${STAGING_BINDIR}/crossscripts \
|
|
--libdir=${libdir} \
|
|
"
|
|
|
|
export TK_LIBRARY = '${libdir}/tk${VER}'
|
|
|
|
do_install:append() {
|
|
ln -sf libtk${VER}.so ${D}${libdir}/libtk${VER}.so.0
|
|
oe_libinstall -so libtk${VER} ${D}${libdir}
|
|
ln -sf wish${VER} ${D}${bindir}/wish
|
|
|
|
sed -i "s;-L${B};-L${STAGING_LIBDIR};g" tkConfig.sh
|
|
sed -i "s;'${WORKDIR};'${STAGING_INCDIR};g" tkConfig.sh
|
|
install -d ${D}${bindir_crossscripts}
|
|
install -m 0755 tkConfig.sh ${D}${bindir_crossscripts}
|
|
}
|
|
|
|
PACKAGECONFIG ??= "xft"
|
|
PACKAGECONFIG[xft] = "--enable-xft,--disable-xft,xft"
|
|
PACKAGECONFIG[xss] = "--enable-xss,--disable-xss,libxscrnsaver libxext"
|
|
|
|
PACKAGES =+ "${PN}-lib"
|
|
|
|
FILES:${PN}-lib = "${libdir}/libtk${VER}.so*"
|
|
FILES:${PN} += "${libdir}/tk*"
|
|
|
|
# isn't getting picked up by shlibs code
|
|
RDEPENDS:${PN} += "tk8-lib"
|
|
RDEPENDS:${PN}:class-native = ""
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# Fix the path in sstate
|
|
SSTATE_SCAN_FILES += "*Config.sh"
|
|
|
|
inherit binconfig
|
|
|
|
SYSROOT_DIRS += "${bindir_crossscripts}"
|
|
|
|
# Fix some paths that might be used by Tcl extensions
|
|
BINCONFIG_GLOB = "*Config.sh"
|
|
|
|
# Cleanup host path from ${libdir}/tclConfig.sh and remove the
|
|
# ${bindir_crossscripts}/tclConfig.sh from target
|
|
PACKAGE_PREPROCESS_FUNCS += "tcl_package_preprocess"
|
|
tcl_package_preprocess() {
|
|
sed -i -e "s;${DEBUG_PREFIX_MAP};;g" \
|
|
-e "s;-L${STAGING_LIBDIR};-L${libdir};g" \
|
|
-e "s;${STAGING_INCDIR};${includedir};g" \
|
|
-e "s;--sysroot=${RECIPE_SYSROOT};;g" \
|
|
${PKGD}${libdir}/tkConfig.sh
|
|
|
|
rm -f ${PKGD}${bindir_crossscripts}/tkConfig.sh
|
|
}
|