mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
fc78d37ff0
Please see https://git.yoctoproject.org/poky/commit/?id=4dd321f8b83afecd962393101b2a6861275b5265 for what changes are needed, and sed commands that can be used to make them en masse. I've verified that bitbake -c patch world works with these, but did not run a world build; the majority of recipes shouldn't need further fixups, but if there are some that still fall out, they can be fixed in followups. Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
56 lines
1.5 KiB
BlitzBasic
56 lines
1.5 KiB
BlitzBasic
SUMMARY = "A library for text mode user interfaces"
|
|
|
|
DESCRIPTION = "Newt is a programming library for color text mode, widget based user \
|
|
interfaces. Newt can be used to add stacked windows, entry widgets, \
|
|
checkboxes, radio buttons, labels, plain text fields, scrollbars, \
|
|
etc., to text mode user interfaces. This package also contains the \
|
|
shared library needed by programs built with newt, as well as a \
|
|
/usr/bin/dialog replacement called whiptail. Newt is based on the \
|
|
slang library."
|
|
|
|
HOMEPAGE = "https://releases.pagure.org/newt/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "LGPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2"
|
|
|
|
# slang needs to be >= 2.2
|
|
DEPENDS = "slang popt python3"
|
|
|
|
SRC_URI = "https://releases.pagure.org/newt/newt-${PV}.tar.gz \
|
|
file://cross_ar.patch \
|
|
file://Makefile.in-Add-tinfo-library-to-the-linking-librari.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "ef0ca9ee27850d1a5c863bb7ff9aa08096c9ed312ece9087b30f3a426828de82"
|
|
|
|
S = "${UNPACKDIR}/newt-${PV}"
|
|
|
|
inherit autotools-brokensep python3native python3-dir python3targetconfig
|
|
|
|
EXTRA_OECONF = "--without-tcl --with-python"
|
|
|
|
EXTRA_OEMAKE += "PYTHONVERS=${PYTHON_DIR}"
|
|
|
|
CLEANBROKEN = "1"
|
|
|
|
export CPPFLAGS
|
|
|
|
PACKAGES:prepend = "whiptail ${PN}-python "
|
|
|
|
RDEPENDS:${PN}-python += "python3-core"
|
|
FILES:${PN}-python = "${PYTHON_SITEPACKAGES_DIR}/*"
|
|
|
|
do_configure:prepend() {
|
|
sh autogen.sh
|
|
}
|
|
|
|
do_compile:prepend() {
|
|
# Make sure the recompile is OK
|
|
rm -f ${B}/.depend
|
|
}
|
|
|
|
FILES:whiptail = "${bindir}/whiptail"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|