mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
6f55248a59
Affected components: - cpupower - intel-speed-select - spidev-test When the externalsrc class is used the tasks listed in SRCTREECOVEREDTASKS are deleted to prevent them being executed. If externalsrc is used for the kernel then this will include virtual/kernel:do_patch. Signed-off-by: Andrej Valek <andrej.v@skyrain.eu> Signed-off-by: Khem Raj <raj.khem@gmail.com>
36 lines
919 B
BlitzBasic
36 lines
919 B
BlitzBasic
SUMMARY = "Shows and sets processor power related values"
|
|
DESCRIPTION = "cpupower is a collection of tools to examine and tune power \
|
|
saving related features of your processor."
|
|
LICENSE = "GPL-2.0-only"
|
|
DEPENDS = "pciutils gettext-native"
|
|
PROVIDES = "virtual/cpupower"
|
|
|
|
inherit kernelsrc kernel-arch bash-completion
|
|
|
|
do_populate_lic[depends] += "virtual/kernel:do_shared_workdir"
|
|
|
|
EXTRA_OEMAKE = "-C ${S}/tools/power/cpupower O=${B} CROSS=${TARGET_PREFIX} CC="${CC}" LD="${LD}" AR=${AR} ARCH=${ARCH}"
|
|
|
|
do_configure[depends] += "virtual/kernel:do_shared_workdir"
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} install
|
|
# Do not ship headers
|
|
rm -rf ${D}${includedir}
|
|
chown -R root:root ${D}
|
|
}
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
RDEPENDS:${PN} = "bash"
|
|
|
|
python do_package:prepend() {
|
|
d.setVar('PKGV', d.getVar("KERNEL_VERSION").split("-")[0])
|
|
}
|
|
|
|
B = "${WORKDIR}/${BPN}-${PV}"
|