mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
fc78d37ff0
Please see https://git.yoctoproject.org/poky/commit/?id=4dd321f8b83afecd962393101b2a6861275b5265 for what changes are needed, and sed commands that can be used to make them en masse. I've verified that bitbake -c patch world works with these, but did not run a world build; the majority of recipes shouldn't need further fixups, but if there are some that still fall out, they can be fixed in followups. Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
51 lines
1.4 KiB
BlitzBasic
51 lines
1.4 KiB
BlitzBasic
SUMMARY = "VPX multi-format codec"
|
|
DESCRIPTION = "The BSD-licensed libvpx reference implementation provides en- and decoders for VP8 and VP9 bitstreams."
|
|
HOMEPAGE = "http://www.webmproject.org/code/"
|
|
BUGTRACKER = "http://code.google.com/p/webm/issues/list"
|
|
SECTION = "libs/multimedia"
|
|
LICENSE = "BSD-3-Clause"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=d5b04755015be901744a78cc30d390d4"
|
|
|
|
SRCREV = "d168454ecd099805c675d4a98c66f4891373302a"
|
|
SRC_URI += "git://chromium.googlesource.com/webm/libvpx;protocol=https;branch=main;tag=v${PV} \
|
|
file://libvpx-configure-support-blank-prefix.patch \
|
|
"
|
|
|
|
|
|
# ffmpeg links with this and fails
|
|
# sysroots/armv4t-oe-linux-gnueabi/usr/lib/libvpx.a(vpx_encoder.c.o)(.text+0xc4): unresolvable R_ARM_THM_CALL relocation against symbol `memcpy@@GLIBC_2.4'
|
|
ARM_INSTRUCTION_SET = "arm"
|
|
|
|
CFLAGS += "-fPIC"
|
|
BUILD_LDFLAGS += "-pthread"
|
|
|
|
export CC
|
|
export LD = "${CC}"
|
|
|
|
VPXTARGET:armv7a = "${@bb.utils.contains("TUNE_FEATURES","neon","armv7-linux-gcc","generic-gnu",d)}"
|
|
VPXTARGET ?= "generic-gnu"
|
|
|
|
CONFIGUREOPTS = " \
|
|
--target=${VPXTARGET} \
|
|
--enable-vp9 \
|
|
--enable-libs \
|
|
--disable-install-docs \
|
|
--disable-static \
|
|
--enable-shared \
|
|
--prefix=${prefix} \
|
|
--libdir=${libdir} \
|
|
--size-limit=16384x16384 \
|
|
"
|
|
|
|
do_configure() {
|
|
${S}/configure ${CONFIGUREOPTS}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
chown -R root:root ${D}
|
|
}
|
|
|
|
BBCLASSEXTEND += "native"
|