mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
fc78d37ff0
Please see https://git.yoctoproject.org/poky/commit/?id=4dd321f8b83afecd962393101b2a6861275b5265 for what changes are needed, and sed commands that can be used to make them en masse. I've verified that bitbake -c patch world works with these, but did not run a world build; the majority of recipes shouldn't need further fixups, but if there are some that still fall out, they can be fixed in followups. Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
43 lines
1.6 KiB
BlitzBasic
43 lines
1.6 KiB
BlitzBasic
SUMMARY = "Term::ReadKey - A perl module for simple terminal control."
|
|
DESCRIPTION = "Term::ReadKey is a compiled perl module dedicated to providing simple \
|
|
control over terminal driver modes (cbreak, raw, cooked, etc.,) support \
|
|
for non-blocking reads, if the architecture allows, and some generalized \
|
|
handy functions for working with terminals. One of the main goals is to \
|
|
have the functions as portable as possible, so you can just plug in 'use \
|
|
Term::ReadKey' on any architecture and have a good likelihood of it \
|
|
working."
|
|
HOMEPAGE = "https://metacpan.org/release/JSTOWE/TermReadKey-2.38"
|
|
SECTION = "libraries"
|
|
|
|
LICENSE = "Artistic-1.0 | GPL-1.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://README;md5=c275db663c8489a5709ebb22b185add5"
|
|
|
|
SRC_URI = "${CPAN_MIRROR}/authors/id/J/JS/JSTOWE/TermReadKey-${PV}.tar.gz"
|
|
|
|
SRC_URI[sha256sum] = "5a645878dc570ac33661581fbb090ff24ebce17d43ea53fd22e105a856a47290"
|
|
|
|
S = "${UNPACKDIR}/TermReadKey-${PV}"
|
|
|
|
UPSTREAM_CHECK_URI = "https://metacpan.org/release/TermReadKey"
|
|
UPSTREAM_CHECK_REGEX = "TermReadKey\-(?P<pver>(\d+\.\d+))(?!_\d+)\.tar.gz"
|
|
|
|
# It needs depend on native to let dynamic loader use native modules
|
|
# rather than target ones.
|
|
DEPENDS = "libterm-readkey-perl-native"
|
|
|
|
inherit cpan ptest-perl
|
|
|
|
RDEPENDS:${PN}-ptest += " \
|
|
perl-module-test-more \
|
|
"
|
|
|
|
do_configure:append () {
|
|
# Hack the dynamic module loader so that it use native modules since it can't load
|
|
# the target ones.
|
|
if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
|
|
sed -i -e "s#-I\$(INST_ARCHLIB)#-I${STAGING_BINDIR_NATIVE}/perl-native/perl/vendor_perl/${@get_perl_version(d)}#g" Makefile
|
|
fi
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|