mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
0127e0b1e8
fixes: ../sources/gnome-software-49.1/meson.build:218:32: ERROR: Could not get pkg-config variable and no default provided for <PkgConfigDependency flatpak: True ['>= 1.14.1']> Signed-off-by: Markus Volk <f_l_k@t-online.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
45 lines
1.5 KiB
BlitzBasic
45 lines
1.5 KiB
BlitzBasic
SUMMARY = "GNOME Software allows users to easily find, discover and install apps."
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
GTKDOC_MESON_OPTION ?= "gtk_doc"
|
|
|
|
inherit gnomebase gsettings itstool gnome-help gtk-icon-cache gtk-doc mime mime-xdg gettext upstream-version-is-even features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "x11 polkit systemd pam"
|
|
|
|
DEPENDS += " \
|
|
appstream \
|
|
gdk-pixbuf \
|
|
glib-2.0 \
|
|
glib-2.0-native \
|
|
gsettings-desktop-schemas \
|
|
gtk4 \
|
|
iso-codes \
|
|
json-glib \
|
|
libadwaita \
|
|
libgudev \
|
|
libsoup-3.0 \
|
|
libxmlb-native \
|
|
polkit \
|
|
"
|
|
|
|
RDEPENDS:${PN} = "iso-codes"
|
|
|
|
EXTRA_OEMESON += "-Dtests=false"
|
|
|
|
SRC_URI += "file://0001-meson.build-dont-look-for-flatpak-http_backend-varia.patch"
|
|
SRC_URI[archive.sha256sum] = "49dfeca77928801756d0c5386c1d20454ca077600a5d1ed66ec46ee33a32c66d"
|
|
|
|
PACKAGECONFIG ?= "flatpak"
|
|
PACKAGECONFIG[flatpak] = "-Dflatpak=true,-Dflatpak=false,flatpak ostree"
|
|
PACKAGECONFIG[snap] = "-Dsnap=true,-Dsnap=false,snapd-glib"
|
|
PACKAGECONFIG[gtk_doc] = "-Dgtk_doc=true,-Dgtk_doc=false,libxslt-native docbook-xsl-stylesheets"
|
|
PACKAGECONFIG[man] = "-Dman=true,-Dman=false,libxslt-native docbook-xsl-stylesheets"
|
|
PACKAGECONFIG[packagekit] = "-Dpackagekit=true,-Dpackagekit=false,gnome-packagekit,gnome-packagekit"
|
|
PACKAGECONFIG[fwupd] = "-Dfwupd=true,-Dfwupd=false,fwupd,fwupd"
|
|
PACKAGECONFIG[malcontent] = "-Dmalcontent=true,-Dmalcontent=false,malcontent"
|
|
|
|
FILES:${PN} += "${datadir} ${systemd_user_unitdir}"
|
|
FILES:${PN}-dev += "${libdir}/gnome-software/libgnomesoftware.so"
|