mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-04 16:10:10 +00:00
54216335fc
Use the update-alternatives class rather than explicit
pkg_prerm_${PN} and pkg_postinst_${PN} tasks. This allows
the configuration to happen at build time rather than
on first boot.
Signed-off-by: Drew Moseley <drew_moseley@mentor.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
36 lines
1.3 KiB
BlitzBasic
36 lines
1.3 KiB
BlitzBasic
SUMMARY = "Miscellaneous utilities specific to Debian"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2 & SMAIL_GPL"
|
|
LIC_FILES_CHKSUM = "file://debian/copyright;md5=f01a5203d50512fc4830b4332b696a9f"
|
|
|
|
SRC_URI = "${DEBIAN_MIRROR}/main/d/${BPN}/${BPN}_${PV}.tar.gz"
|
|
SRC_URI[md5sum] = "c0cb076754d7f4eb1e3397d00916647f"
|
|
SRC_URI[sha256sum] = "190850cdd6b5302e0a1ba1aaed1bc7074d67d3bd8d04c613f242f7145afa53a6"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
do_configure_prepend() {
|
|
sed -i -e 's:tempfile.1 which.1:which.1:g' ${S}/Makefile.am
|
|
}
|
|
|
|
do_install_append() {
|
|
if [ "${base_bindir}" != "${bindir}" ]; then
|
|
# Debian places some utils into ${base_bindir} as does busybox
|
|
install -d ${D}${base_bindir}
|
|
for app in run-parts tempfile; do
|
|
mv ${D}${bindir}/$app ${D}${base_bindir}/$app
|
|
done
|
|
fi
|
|
}
|
|
|
|
ALTERNATIVE_PRIORITY="100"
|
|
ALTERNATIVE_${PN} = "add-shell installkernel remove-shell run-parts savelog tempfile which"
|
|
|
|
ALTERNATIVE_LINK_NAME[add-shell]="${sbindir}/add-shell"
|
|
ALTERNATIVE_LINK_NAME[installkernel]="${sbindir}/installkernel"
|
|
ALTERNATIVE_LINK_NAME[remove-shell]="${sbindir}/remove-shell"
|
|
ALTERNATIVE_LINK_NAME[run-parts]="${base_bindir}/run-parts"
|
|
ALTERNATIVE_LINK_NAME[savelog]="${bindir}/savelog"
|
|
ALTERNATIVE_LINK_NAME[tempfile]="${base_bindir}/tempfile"
|
|
ALTERNATIVE_LINK_NAME[which]="${bindir}/which"
|