mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-04 16:10:10 +00:00
1de4086b38
* switched to gnu11 in:
https://git.kernel.org/pub/scm/fs/xfs/xfstests-dev.git/commit/?id=77aab5c2bfc9135fde66c17286ca4be87b417f39
* add one more commit to unionmount-testsuite
c6ab621ac1
* fixes:
http://errors.yoctoproject.org/Errors/Details/852985/
* add pkgconfig used since:
https://git.kernel.org/pub/scm/fs/xfs/xfstests-dev.git/commit/?id=1ba4f6f4bcd2aaef18e9549da89c3f0976f3fd01
to fix:
http://errors.yoctoproject.org/Errors/Details/852995/
configure:15434: error: possibly undefined macro: AC_DEFINE
If this token and others are legitimate, please use m4_pattern_allow.
See the Autoconf documentation.
configure:15435: error: possibly undefined macro: AC_DEFINE_UNQUOTED
Signed-off-by: Martin Jansa <martin.jansa@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
79 lines
2.8 KiB
BlitzBasic
79 lines
2.8 KiB
BlitzBasic
SUMMARY = "File system QA test suite"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://LICENSES/GPL-2.0;md5=74274e8a218423e49eefdea80bc55038"
|
|
|
|
SRCREV = "b59671d2b894040bd355ddbf1ff03285607de16f"
|
|
SRCREV_unionmount = "c6ab621ac19f2b96d34cd98f244e611750e2bb23"
|
|
SRCREV_FORMAT = "default_unionmount"
|
|
|
|
SRC_URI = "git://git.kernel.org/pub/scm/fs/xfs/xfstests-dev.git;branch=master;tag=v${PV} \
|
|
git://github.com/amir73il/unionmount-testsuite.git;branch=master;protocol=https;name=unionmount;destsuffix=unionmount-testsuite \
|
|
file://0001-add-missing-FTW_-macros-when-not-available-in-libc.patch \
|
|
file://0002-Drop-detached_mounts_propagation-and-remove-sys-moun.patch \
|
|
file://0001-include-libgen.h-for-basename-API-prototype.patch \
|
|
file://0002-Add-missing-STATX_ATTR_-defines-from-musl-sys-stat.h.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# brokensep because m4/package_globals.m4 calls ". ./VERSION" (and that's not the only issue)
|
|
inherit autotools-brokensep useradd pkgconfig
|
|
|
|
DEPENDS += "xfsprogs acl"
|
|
RDEPENDS:${PN} += "\
|
|
bash \
|
|
bc \
|
|
coreutils \
|
|
e2fsprogs \
|
|
e2fsprogs-tune2fs \
|
|
e2fsprogs-resize2fs \
|
|
libaio \
|
|
libcap-bin \
|
|
overlayfs-tools \
|
|
perl \
|
|
python3 \
|
|
python3-core \
|
|
xfsprogs \
|
|
acl \
|
|
gawk \
|
|
util-linux-mkfs \
|
|
util-linux-mount \
|
|
util-linux-findmnt \
|
|
inetutils-hostname \
|
|
grep \
|
|
"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
# these users are necessary to run the tests
|
|
USERADD_PARAM:${PN} = "-U -m fsgqa; -N 123456-fsgqa; -N fsgqa2"
|
|
|
|
EXTRA_OECONF = "INSTALL_USER=root INSTALL_GROUP=root"
|
|
|
|
TARGET_CC_ARCH:append:libc-musl = " -D_LARGEFILE64_SOURCE"
|
|
|
|
do_configure:prepend() {
|
|
# this is done by Makefile configure target, but we don't call it in do_configure
|
|
cp -a ${S}/include/install-sh .
|
|
}
|
|
|
|
do_install() {
|
|
# otherwise install-sh duplicates DESTDIR prefix
|
|
export DIST_ROOT="/" DIST_MANIFEST="" DESTDIR="${D}"
|
|
oe_runmake install
|
|
|
|
unionmount_target_dir=${D}${prefix}/xfstests/unionmount-testsuite
|
|
install -d $unionmount_target_dir/tests
|
|
install ${UNPACKDIR}/unionmount-testsuite/tests/* -t $unionmount_target_dir/tests
|
|
install ${UNPACKDIR}/unionmount-testsuite/*.py -t $unionmount_target_dir
|
|
install ${UNPACKDIR}/unionmount-testsuite/run -t $unionmount_target_dir
|
|
install ${UNPACKDIR}/unionmount-testsuite/README -t $unionmount_target_dir
|
|
}
|
|
|
|
FILES:${PN} += "${prefix}/xfstests"
|
|
|
|
# This one is reproducible only on 32bit MACHINEs
|
|
# http://errors.yoctoproject.org/Errors/Details/766963/
|
|
# lstat64.c:65:14: error: passing argument 1 of 'time' from incompatible pointer type [-Wincompatible-pointer-types]
|
|
# bstat.c:18:19: error: passing argument 1 of 'ctime' from incompatible pointer type [-Wincompatible-pointer-types]
|
|
CFLAGS += "-Wno-error=incompatible-pointer-types"
|