mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
80e9601cc8
Similar to "core-image-ptest: Switch to BBCLASSEXTEND parallel execution" Refactor meta-python-ptest-image.bb for an image per ptest in the form of meta-python-ptest-image-XXX using class extensions. * Add meta-python-ptest-all-image.bb depends on ALL meta-python-ptest-image-XXX in meta-python * Add meta-python-ptest-fast-image.bb depends on meta-python ptests which take less than ~30s This allows parallel execution of the tests. The downside to this approach is the parsing time of an image generating this number of class extensions is slow but making it easier to execute and collect test data should outweigh that. A useful advantage is that the dependencies of each ptest package are checked/tested individually. Add to local.conf: IMAGE_CLASSES += "testimage" All the meta-python-ptest-image-XXX can be built with: $ bitbake meta-python-ptest-all-image Subsequently, all the ptest images can be run with: $ bitbake -c testimage meta-python-ptest-all-image You will likely want to limit the number of parallel image tests: BB_NUMBER_THREADS = "4" based on the number of TAP devices you have defined or the number of simultaneous QEMU sessions your server can support. Results can be summarized with: $ resulttool report tmp/log/oeqa/testresults.json Signed-off-by: Tim Orling <tim.orling@konsulko.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
26 lines
870 B
BlitzBasic
26 lines
870 B
BlitzBasic
DESCRIPTION = "Recipe to trigger execution of all meta-python ptest images."
|
|
HOMEPAGE = "https://www.openembedded.org/"
|
|
|
|
LICENSE = "MIT"
|
|
|
|
inherit features_check nopackages
|
|
REQUIRED_DISTRO_FEATURES = "ptest"
|
|
|
|
require conf/include/ptest-packagelists-meta-python.inc
|
|
|
|
# Include the full set of ptests
|
|
PTESTS_META_PYTHON = "${PTESTS_FAST_META_PYTHON} ${PTESTS_SLOW_META_PYTHON}"
|
|
|
|
do_testimage[noexec] = "1"
|
|
do_testimage[depends] = "${@' '.join(['meta-python-ptest-image-'+x+':do_testimage' for x in d.getVar('PTESTS_META_PYTHON').split()])}"
|
|
|
|
do_build[depends] = "${@' '.join(['meta-python-ptest-image-'+x+':do_build' for x in d.getVar('PTESTS_META_PYTHON').split()])}"
|
|
|
|
# normally image.bbclass would do this
|
|
EXCLUDE_FROM_WORLD = "1"
|
|
|
|
python () {
|
|
if bb.utils.contains('IMAGE_CLASSES', 'testimage', True, False, d):
|
|
bb.build.addtask("do_testimage", "", "", d)
|
|
}
|