mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
a275078cbe
Details: https://nvd.nist.gov/vuln/detail/CVE-2025-10824 The upstream maintainer wasn't able to reproduce the issue[1], and the related bug is closed without further action. [1]: https://github.com/axboe/fio/issues/1981 Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
50 lines
1.9 KiB
BlitzBasic
50 lines
1.9 KiB
BlitzBasic
SUMMARY = "Filesystem and hardware benchmark and stress tool"
|
|
DESCRIPTION = "fio is an I/O tool meant to be used both for benchmark and \
|
|
stress/hardware verification. It has support for a number of I/O engines, \
|
|
I/O priorities (for newer Linux kernels), rate I/O, forked or threaded jobs, \
|
|
and much more. It can work on block devices as well as files. fio accepts \
|
|
job descriptions in a simple-to-understand text format. Several example job \
|
|
files are included. fio displays all sorts of I/O performance information."
|
|
HOMEPAGE = "http://freecode.com/projects/fio"
|
|
SECTION = "console/tests"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = "libaio zlib coreutils-native"
|
|
DEPENDS += "${@bb.utils.contains('MACHINE_FEATURES', 'pmem', 'pmdk', '', d)}"
|
|
RDEPENDS:${PN} = "python3-core bash"
|
|
|
|
PACKAGECONFIG_NUMA = "numa"
|
|
# ARM does not currently support NUMA
|
|
PACKAGECONFIG_NUMA:arm = ""
|
|
PACKAGECONFIG_NUMA:armeb = ""
|
|
|
|
PACKAGECONFIG ??= "${PACKAGECONFIG_NUMA}"
|
|
PACKAGECONFIG[numa] = ",--disable-numa,numactl"
|
|
|
|
SRC_URI = "git://git.kernel.dk/fio.git;branch=master"
|
|
SRCREV = "a6e474c9e896e4ba1eb40066a03402afb040710a"
|
|
|
|
SRC_URI += "file://CVE-2025-10823.patch"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "fio-(?P<pver>\d+(\.\d+)+)"
|
|
|
|
|
|
# avoids build breaks when using no-static-libs.inc
|
|
DISABLE_STATIC = ""
|
|
|
|
EXTRA_OEMAKE = "CC='${CC}' LDFLAGS='${LDFLAGS}'"
|
|
EXTRA_OECONF = "${@bb.utils.contains('MACHINE_FEATURES', 'x86', '--disable-optimizations', '', d)}"
|
|
|
|
do_configure() {
|
|
./configure ${EXTRA_OECONF} ${PACKAGECONFIG_CONFARGS}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D} prefix=${prefix} mandir=${mandir}
|
|
install -d ${D}/${docdir}/${PN}
|
|
cp -R --no-dereference --preserve=mode,links -v ${S}/examples ${D}/${docdir}/${PN}/
|
|
}
|
|
|
|
CVE_STATUS[CVE-2025-10824] = "disputed: Maintainer could not reproduce the issue, issue is closed without change."
|