mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
b61588c463
In order to fix the dependency issue on PIL module, python3-pillow is required. Signed-off-by: Adrian Fiergolski <adrian.fiergolski@fastree3d.com> Signed-off-by: Khem Raj <raj.khem@gmail.com> (cherry picked from commitd4e70a1960) Signed-off-by: Armin Kuster <akuster808@gmail.com> (cherry picked from commitfcc7d7eae8) [fixup for honister context] Signed-off-by: Armin Kuster <akuster808@gmail.com>
52 lines
1.5 KiB
BlitzBasic
52 lines
1.5 KiB
BlitzBasic
SUMMARY = "matplotlib: plotting with Python"
|
|
DESCRIPTION = "\
|
|
Matplotlib is a Python 2D plotting library which produces \
|
|
publication-quality figures in a variety of hardcopy formats \
|
|
and interactive environments across platforms."
|
|
HOMEPAGE = "https://github.com/matplotlib/matplotlib"
|
|
SECTION = "devel/python"
|
|
LICENSE = "PSF"
|
|
LIC_FILES_CHKSUM = "\
|
|
file://setup.py;beginline=282;endline=282;md5=20e7ab4d2b2b1395a0e4ab800181eb96 \
|
|
file://LICENSE/LICENSE;md5=afec61498aa5f0c45936687da9a53d74 \
|
|
"
|
|
DEPENDS = "\
|
|
freetype \
|
|
libpng \
|
|
python3-numpy-native \
|
|
python3-dateutil-native \
|
|
python3-pytz-native \
|
|
python3-certifi-native \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "84d4c4f650f356678a5d658a43ca21a41fca13f9b8b00169c0b76e6a6a948908"
|
|
|
|
inherit pypi setuptools3 pkgconfig
|
|
|
|
# LTO with clang needs lld
|
|
LDFLAGS:append:toolchain-clang = " -fuse-ld=lld"
|
|
LDFLAGS:remove:toolchain-clang:mips = "-fuse-ld=lld"
|
|
|
|
RDEPENDS:${PN} = "\
|
|
freetype \
|
|
libpng \
|
|
python3-numpy \
|
|
python3-pyparsing \
|
|
python3-cycler \
|
|
python3-dateutil \
|
|
python3-kiwisolver \
|
|
python3-pytz \
|
|
python3-pillow \
|
|
"
|
|
|
|
ENABLELTO:toolchain-clang:riscv64 = "echo enable_lto = False >> ${S}/setup.cfg"
|
|
ENABLELTO:toolchain-clang:riscv32 = "echo enable_lto = False >> ${S}/setup.cfg"
|
|
ENABLELTO:toolchain-clang:mips = "echo enable_lto = False >> ${S}/setup.cfg"
|
|
do_compile:prepend() {
|
|
echo [libs] > ${S}/setup.cfg
|
|
echo system_freetype = true >> ${S}/setup.cfg
|
|
${ENABLELTO}
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|