mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-04 16:10:10 +00:00
855726266a
Changelog: =========== - Fix initialization in GPU-aware builds when no devices are present - Fix internal pmix.h header conflict when building with an external PMIx library. - Fix build issue with Slurm by removing dependency on libslurm and always using internal logic for parsing the Slurm hostfile. - Fix potential stale GPU IPC handle usage resulting in data corruption or crashes - Update XPMEM thresholds to avoid excessive buffer mapping overhead - Fix potential hang in ROMIO when setting info hints on certain files - Improved detection of incompatible PMI[x] client/server configuration - Fix use of PMIX_PREFIX attribute for certain versions of OpenPMIx - Fix Intel GPU output with MPIR_CVAR_DEBUG_SUMMARY - Fix F08 binding compilation with nvfortran - Fix line continuation Hydra's --configfile option - Fix valgrind uninitialized read warnings in ch3 - Fix missing mpixxx_opts.conf file with help text for mpicc and friends - Fixes for several compiler warnings Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
68 lines
2.2 KiB
BlitzBasic
68 lines
2.2 KiB
BlitzBasic
SUMMARY = "Message Passing Interface (MPI) implementation"
|
|
HOMEPAGE = "http://www.mpich.org/"
|
|
SECTION = "devel"
|
|
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=3a296dfb961b957b0e8adf67d8478d3d"
|
|
|
|
SRC_URI = "http://www.mpich.org/static/downloads/${PV}/mpich-${PV}.tar.gz"
|
|
SRC_URI[sha256sum] = "acc11cb2bdc69678dc8bba747c24a28233c58596f81f03785bf2b7bb7a0ef7dc"
|
|
|
|
RDEPENDS:${PN} += "bash perl libxml2"
|
|
|
|
EXTRA_OECONF = "--enable-debuginfo \
|
|
--enable-fast \
|
|
--enable-shared \
|
|
--with-pm=gforker \
|
|
BASH_SHELL='${USRBINPATH}/env bash' \
|
|
PERL='${USRBINPATH}/env perl' \
|
|
--with-device=ch3:nemesis \
|
|
"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
|
|
PACKAGECONFIG[cxx] = "--enable-cxx,--disable-cxx"
|
|
PACKAGECONFIG[fortran] = "--with-cross=${WORKDIR}/cross_values.txt --enable-fortran,--disable-f77 --disable-fortran,libgfortran"
|
|
|
|
# libmpi.so needs symbols like __multf3 and somehow it does not respect --rtlib option passed by clang
|
|
LDFLAGS:append:x86-64 = " -lgcc"
|
|
LDFLAGS:append:x86 = " -lgcc"
|
|
|
|
inherit autotools gettext pkgconfig qemu
|
|
|
|
DEPENDS += "qemu-native"
|
|
|
|
do_configure() {
|
|
if [ "${@bb.utils.contains('PACKAGECONFIG', 'fortran', '1', '', d)}" = "1" ]; then
|
|
qemu_binary="${@qemu_wrapper_cmdline(d, d.getVar('STAGING_DIR_HOST'), [d.expand('${STAGING_DIR_HOST}${libdir}'),d.expand('${STAGING_DIR_HOST}${base_libdir}')])}"
|
|
cat > ${WORKDIR}/qemuwrapper << EOF
|
|
#!/bin/sh
|
|
$qemu_binary "\$@"
|
|
EOF
|
|
chmod +x ${WORKDIR}/qemuwrapper
|
|
|
|
sed -i 's:my \(.*\) ./t`;:my \1 ${WORKDIR}/qemuwrapper ${WORKDIR}/t`;:' ${S}/maint/gen_cross.pl
|
|
|
|
cd ${WORKDIR}
|
|
perl ${S}/maint/gen_cross.pl
|
|
|
|
sed -i 's:\(CROSS_F90_INTEGER_MODEL_MAP=.*\) }"$:\1 }, ":' ${WORKDIR}/cross_values.txt
|
|
fi
|
|
|
|
cd ${S}
|
|
./autogen.sh
|
|
|
|
cd ${B}
|
|
oe_runconf
|
|
sed -i -e 's,${WORKDIR},,g' ${B}/src/include/mpichinfo.h
|
|
}
|
|
|
|
do_install:append() {
|
|
sed -i 's,${S}/,,g' ${D}/${libdir}/libmpi.la
|
|
sed -i 's,${DEBUG_PREFIX_MAP},,g' ${D}${bindir}/mpicxx
|
|
sed -i 's,${DEBUG_PREFIX_MAP},,g' ${D}${bindir}/mpicc
|
|
sed -i 's,${DEBUG_PREFIX_MAP},,g' ${D}/${libdir}/pkgconfig/mpich.pc
|
|
sed -i 's,${RECIPE_SYSROOT},/,g' ${D}${bindir}/mpicc
|
|
sed -i 's,${RECIPE_SYSROOT},/,g' ${D}${bindir}/mpicxx
|
|
}
|