mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-01 13:58:06 +00:00
f2b8b47e45
License-Update: the project was relicensed from GPL-2 to GPL-3 Inludes fixes for the following vulnerabilities: CVE-2025-7394, CVE-2025-7395, CVE-2025-7396, CVE-2025-12888, CVE-2025-11936, CVE-2025-11935, CVE-2025-11934, CVE-2025-11933, CVE-2025-11932, CVE-2025-11931, CVE-2025-12889 Drop patch that is incorporated in this release. Changelog: https://github.com/wolfSSL/wolfssl/blob/master/ChangeLog.md Ptests passed: START: ptest-runner 2025-12-09T18:23 BEGIN: /usr/lib/wolfssl/ptest Wolfssl ptest logs are stored in /tmp/wolfss_temp.6rsnys/ptest.log Test script returned: 0 unit_test: Success for all configured tests. PASS: Wolfssl DURATION: 13 END: /usr/lib/wolfssl/ptest 2025-12-09T18:23 STOP: ptest-runner TOTAL: 1 FAIL: 0 Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
49 lines
1.7 KiB
BlitzBasic
49 lines
1.7 KiB
BlitzBasic
SUMMARY = "wolfSSL Lightweight Embedded SSL/TLS Library"
|
|
DESCRIPTION = "wolfSSL, formerly CyaSSL, is a lightweight SSL library written \
|
|
in C and optimized for embedded and RTOS environments. It can \
|
|
be up to 20 times smaller than OpenSSL while still supporting \
|
|
a full TLS client and server, up to TLS 1.3"
|
|
HOMEPAGE = "https://www.wolfssl.com/products/wolfssl"
|
|
BUGTRACKER = "https://github.com/wolfssl/wolfssl/issues"
|
|
SECTION = "libs"
|
|
LICENSE = "GPL-3.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
PROVIDES += "cyassl"
|
|
RPROVIDES:${PN} = "cyassl"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/wolfSSL/wolfssl.git;protocol=https;branch=master;tag=v${PV}-stable \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRCREV = "59f4fa568615396fbf381b073b220d1e8d61e4c2"
|
|
|
|
|
|
inherit autotools ptest
|
|
|
|
EXTRA_OECONF += "--enable-certreq --enable-dtls --enable-opensslextra --enable-certext --enable-certgen"
|
|
|
|
PACKAGECONFIG ?= "reproducible-build"
|
|
|
|
PACKAGECONFIG[reproducible-build] = "--enable-reproducible-build,--disable-reproducible-build,"
|
|
BBCLASSEXTEND += "native nativesdk"
|
|
|
|
CFLAGS += '-fPIC -DCERT_REL_PREFIX=\\"./\\"'
|
|
|
|
RDEPENDS:${PN}-ptest += " bash"
|
|
|
|
do_install_ptest() {
|
|
# Prevent QA Error "package contains reference to TMPDIR [buildpaths]" for unit.test script
|
|
# Replace the occurences of ${B}/src with '${PTEST_PATH}'
|
|
sed -i 's|${B}/src|${PTEST_PATH}|g' ${B}/tests/unit.test
|
|
|
|
install -d ${D}${PTEST_PATH}/test
|
|
|
|
# create an empty folder examples, needed in wolfssl's tests/api.c to "Test loading path with no files"
|
|
install -d ${D}${PTEST_PATH}/examples
|
|
cp -rf ${B}/tests/. ${D}${PTEST_PATH}/test
|
|
cp -rf ${S}/certs ${D}${PTEST_PATH}
|
|
cp -rf ${S}/tests ${D}${PTEST_PATH}
|
|
}
|