mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-04 16:10:10 +00:00
f7caccedc7
Change log found at https://gitlab.xfce.org/xfce/xfce4-panel/-/tags/xfce4-panel-4.18.6 - Update copyright year - Do not use g_log_set_always_fatal() - launcher: Ensure default icon in empty launchers - build: Search for bind_textdomain_codeset in libintl too - Fix memory management of GTypeModules - pager: Avoid recursion in WnckScren signal handler - pager: Do not query workspace count if screen is not initialized - libxfce4panel: Fix custom menu items management - clock: Create monitor proxy asynchronously - Add missing G_BEGIN_DECLS - Translation Updates: Czech, Finnish, Hungarian, Icelandic, Interlingue, Italian, Portuguese (Brazil), Turkish Signed-off-by: Jason Schonberg <schonm@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
45 lines
1.6 KiB
BlitzBasic
45 lines
1.6 KiB
BlitzBasic
SUMMARY = "Xfce4 Panel"
|
|
SECTION = "x11"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=26a8bd75d8f8498bdbbe64a27791d4ee"
|
|
DEPENDS = "garcon exo gtk+3 cairo virtual/libx11 libxml2 libwnck3 vala-native"
|
|
|
|
inherit xfce gtk-doc gobject-introspection features_check mime-xdg
|
|
|
|
# xfce4 depends on libwnck3, gtk+3 and libepoxy need to be built with x11 PACKAGECONFIG.
|
|
# cairo would at least needed to be built with xlib.
|
|
ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
|
|
|
|
SRC_URI += " \
|
|
file://0001-windowmenu-do-not-display-desktop-icon-when-no-windo.patch \
|
|
file://0002-use-lxdm-to-replace-dm-tool.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "21337161f58bb9b6e42760cb6883bc79beea27882aa6272b61f0e09d750d7c62"
|
|
|
|
EXTRA_OECONF += "--disable-vala"
|
|
|
|
python populate_packages:prepend() {
|
|
plugin_dir = d.expand('${libdir}/xfce4/panel/plugins/')
|
|
plugin_name = d.expand('${PN}-plugin-%s')
|
|
do_split_packages(d, plugin_dir, r'^lib(.*)\.so$', plugin_name,
|
|
'${PN} plugin for %s', extra_depends='', prepend=True,
|
|
aux_files_pattern=['${datadir}/xfce4/panel/plugins/%s.desktop',
|
|
'${sysconfdir}/xdg/xfce/panel/%s-*',
|
|
'${datadir}/icons/hicolor/48x48/apps/*-%s.png',
|
|
'${bindir}/*%s*'])
|
|
}
|
|
|
|
PACKAGES_DYNAMIC += "^${PN}-plugin-.*"
|
|
|
|
PACKAGES =+ "${PN}-gtk3"
|
|
|
|
FILES:${PN} += "${libdir}/xfce4/panel/migrate \
|
|
${libdir}/xfce4/panel/wrapper-1.0"
|
|
|
|
FILES:${PN}-dev += "${libdir}/xfce4/panel/plugins/*.la"
|
|
|
|
FILES:${PN}-gtk3 = " \
|
|
${libdir}/libxfce4panel-2.0${SOLIBS} \
|
|
${libdir}/xfce4/panel/wrapper-2.0 \
|
|
"
|