mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-01-04 16:10:10 +00:00
fd97bae312
License-Update:
Copyright: Update copyright date to end 2023 as appropriate
Add in OSCORE support
RIOT: Update to support latest libcoap code
Add BSD-3-Clause
Changelog:
===========
* Source files reformatted according to pre-commit rules.
* Support for RFC8613 (OSCORE).
* Support for RFC8974 (Extended Tokens).
* Support for RFC9177 (Q-Block).
* Support for latest RIOT code and new examples.
* Support for MinGW builds.
* Support for AF_UNIX sockets.
* Support for WebSockets (RFC8323).
* Support for IPv4 only and IPv6 only libcoap builds.
* Support for defining maximum logging level.
* Support for maintaining Observer requests over server restarts.
* Support for Contiki-NG.
* Support for latest LwIP, including using TinyDTLS.
* libcoap now has protocol layered support, separating out the
logical layers. Stack now is:-
- Application
- libcoap - CoAP
- libcoap - CoAP-Session
- libcoap - (D)TLS I/F using external (D)TLS Library
- libcoap - Netif
- libcoap - Sockets
- Kernel Network Stack
* Fixes CVE-2023-30362 and CVE-2023-35862.
* Reported bugs fixed.
* Examples now support separate logging levels for libcoap and (D)TLS.
* syslog LOG_ logging levels replaced with COAP_LOG_ logging levels.
* New public API functions to aid / reduce application coding.
* Remove requirement for applications to have sockaddr knowledge.
* Support for clients sending IPv4 broadcast requests.
* Documentation added and updated (Doxygen and man).
* Fix ABI version.
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
63 lines
2.2 KiB
BlitzBasic
63 lines
2.2 KiB
BlitzBasic
SUMMARY = "A C implementation of the Constrained Application Protocol"
|
|
DESCRIPTION = "libcoap implements a lightweight application-protocol for \
|
|
devices that are constrained their resources such as computing power, \
|
|
RF range, memory, bandwith, or network packet sizes."
|
|
HOMEPAGE ="https://libcoap.net/"
|
|
|
|
LICENSE = "BSD-2-Clause & BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=1978dbc41673ab1c20e64b287c8317bc"
|
|
|
|
SRC_URI = "git://github.com/obgm/libcoap.git;branch=main;protocol=https \
|
|
file://run-ptest \
|
|
"
|
|
SRCREV = "9cde7cdee171e3f47486c6e70d479fdf49f3d2d6"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools manpages pkgconfig ptest
|
|
|
|
DEPENDS += "ctags-native"
|
|
|
|
PACKAGECONFIG ?= "\
|
|
async openssl tcp \
|
|
${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)} \
|
|
"
|
|
PACKAGECONFIG[async] = "--enable-async,--disable-async"
|
|
PACKAGECONFIG[gnutls] = "--with-gnutls,--without-gnutls,gnutls,,,openssl mbedtls"
|
|
PACKAGECONFIG[manpages] = "--enable-documentation --enable-doxygen --enable-manpages,--disable-documentation,asciidoc-native doxygen-native graphviz-native"
|
|
PACKAGECONFIG[mbedtls] = "--with-mbedtls,--without-mbedtls,mbedtls,,,gnutls openssl"
|
|
PACKAGECONFIG[openssl] = "--with-openssl,--without-openssl,openssl,,,gnutls mbedtls"
|
|
PACKAGECONFIG[small-stack] = "--enable-small-stack,--disable-small-stack"
|
|
PACKAGECONFIG[tcp] = "--enable-tcp,--disable-tcp"
|
|
PACKAGECONFIG[tests] = "--enable-tests,--disable-tests,cunit"
|
|
|
|
EXTRA_OECONF = "\
|
|
--with-epoll --enable-add-default-names \
|
|
--without-tinydtls --without-submodule-tinydtls \
|
|
${@bb.utils.contains_any('PACKAGECONFIG', 'gnutls openssl mbedtls', '--enable-dtls', '--disable-dtls', d)} \
|
|
"
|
|
|
|
python () {
|
|
if d.getVar('PTEST_ENABLED') == "1":
|
|
d.setVar('DISABLE_STATIC', '')
|
|
}
|
|
|
|
export SGML_CATALOG_FILES="file://${STAGING_ETCDIR_NATIVE}/xml/catalog"
|
|
|
|
do_compile:prepend() {
|
|
oe_runmake update-map-file
|
|
}
|
|
|
|
do_install_ptest () {
|
|
install -d ${D}${PTEST_PATH}
|
|
install -m 0755 ${WORKDIR}/run-ptest ${D}${PTEST_PATH}/run-ptest
|
|
install -m 0755 ${B}/tests/testdriver ${D}${PTEST_PATH}/testdriver
|
|
}
|
|
|
|
PACKAGE_BEFORE_PN += "\
|
|
${PN}-bin \
|
|
"
|
|
|
|
FILES:${PN}-bin = "${bindir}"
|
|
FILES:${PN}-dev += "${datadir}/${BPN}/examples"
|