mirror of
git://git.yoctoproject.org/meta-selinux
synced 2026-01-01 13:58:04 +00:00
05178ce178
Remove or update S definitions as required to work with oe-core S/UNPACKDIR changes. A default definition of S has been added to selinux_common.inc to avoid duplication in the set of recipes that use it to build packages from different subdirectories of the selinux repo. The three packagegroups test build successfully with these changes. Signed-off-by: Scott Murray <scott.murray@konsulko.com> Signed-off-by: Yi Zhao <yi.zhao@windriver.com>
32 lines
959 B
BlitzBasic
32 lines
959 B
BlitzBasic
SUMMARY = "SELinux library and simple utilities"
|
|
DESCRIPTION = "libselinux provides an API for SELinux applications to get and set \
|
|
process and file security contexts and to obtain security policy \
|
|
decisions. Required for any applications that use the SELinux API."
|
|
SECTION = "base"
|
|
LICENSE = "PD"
|
|
LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=84b4d2c6ef954a2d4081e775a270d0d0"
|
|
|
|
require selinux_common.inc
|
|
|
|
inherit lib_package pkgconfig
|
|
|
|
FILESEXTRAPATHS:prepend := "${THISDIR}/libselinux:"
|
|
SRC_URI += "\
|
|
file://0003-libselinux-restore-drop-the-obsolete-LSF-transitiona.patch \
|
|
"
|
|
|
|
DEPENDS = "libsepol libpcre2"
|
|
DEPENDS:append:libc-musl = " fts"
|
|
|
|
def get_policyconfigarch(d):
|
|
import re
|
|
target = d.getVar('TARGET_ARCH')
|
|
p = re.compile('i.86')
|
|
target = p.sub('i386',target)
|
|
return "ARCH=%s" % (target)
|
|
|
|
EXTRA_OEMAKE = "${@get_policyconfigarch(d)}"
|
|
EXTRA_OEMAKE:append:libc-musl = " FTS_LDLIBS=-lfts"
|
|
|
|
BBCLASSEXTEND = "native"
|