mirror of
git://git.yoctoproject.org/meta-selinux
synced 2026-01-01 13:58:04 +00:00
4273eb6d6e
ChangeLog: https://github.com/SELinuxProject/selinux/releases/tag/3.8 * libsemanage: Preserve file context and ownership in policy store * libselinux: deprecate security_disable(3) * libsepol: Support nlmsg extended permissions * libsepol: Add policy capability netlink_xperm * libsemanage: Optionally allow duplicate declarations * policycoreutils: introduce unsetfiles * libselinux/utils: introduce selabel_compare * improved selabel_lookup performance * libselinux: support parallel usage of selabel_lookup(3) * libsepol: add support for xperms in conditional policies * Improved man pages * Code improvements and bug fixes * Always build for LFS mode on 32-bit archs. * libsemanage: Mute error messages from selinux_restorecon introduced in 3.8-rc1 * Regex spec ordering is restored to pre 3.8-rc1 * Binary fcontext files format changed, files using old format are ignored * Code improvements and bug fixes License-Update: White space cleanup for libsemanage/LICENSE Signed-off-by: Yi Zhao <yi.zhao@windriver.com> Signed-off-by: Joe MacDonald <joe.macdonald@siemens.com>
59 lines
1.9 KiB
BlitzBasic
59 lines
1.9 KiB
BlitzBasic
|
|
SUMMARY = "Daemon to translate SELinux MCS/MLS sensitivity labels"
|
|
DESCRIPTION = "\
|
|
mcstrans provides an translation daemon to translate SELinux categories \
|
|
from internal representations to user defined representation."
|
|
SECTION = "base"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
require selinux_common.inc
|
|
|
|
inherit pkgconfig systemd update-rc.d
|
|
|
|
SRC_URI += "file://mcstrans-de-bashify.patch \
|
|
file://mcstrans-fix-the-init-script.patch \
|
|
"
|
|
|
|
DEPENDS = "libsepol libselinux libcap"
|
|
|
|
EXTRA_OEMAKE = "SBINDIR=${base_sbindir} \
|
|
INITDIR=${sysconfdir}/init.d \
|
|
SYSTEMDDIR=${systemd_unitdir} \
|
|
"
|
|
|
|
S = "${WORKDIR}/git/mcstrans"
|
|
|
|
do_install:append() {
|
|
install -d ${D}${sbindir}
|
|
install -m 755 utils/untranscon ${D}${sbindir}/
|
|
install -m 755 utils/transcon ${D}${sbindir}/
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
|
|
install -d ${D}${sysconfdir}/tmpfiles.d
|
|
echo "d ${runtimedir}/setrans - - - -" \
|
|
> ${D}${sysconfdir}/tmpfiles.d/setrans.conf
|
|
else
|
|
install -d ${D}${sysconfdir}/default/volatiles
|
|
echo "d root root 0755 /var/run/setrans none" \
|
|
>${D}${sysconfdir}/default/volatiles/80_mcstrans
|
|
fi
|
|
install -d ${D}${datadir}/mcstrans
|
|
cp -r share/* ${D}${datadir}/mcstrans/.
|
|
}
|
|
|
|
SYSTEMD_SERVICE:mcstrans = "mcstrans.service"
|
|
INITSCRIPT_PACKAGES = "mcstrans"
|
|
INITSCRIPT_NAME:mcstrans = "mcstrans"
|
|
INITSCRIPT_PARAMS:mcstrans = "defaults"
|
|
|
|
pkg_postinst:mcstrans () {
|
|
if [ -z "$D" ]; then
|
|
if command -v systemd-tmpfiles >/dev/null; then
|
|
systemd-tmpfiles --create ${sysconfdir}/tmpfiles.d/setrans.conf
|
|
elif [ -e ${sysconfdir}/init.d/populate-volatile.sh ]; then
|
|
${sysconfdir}/init.d/populate-volatile.sh update
|
|
fi
|
|
fi
|
|
}
|