mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-01 13:58:04 +00:00
21400a18cb
The git repo for gnu-config was changed, so update the SRC_URI accordingly with the new link. (From OE-Core rev: 003c12cf67d45338ed4400c99b7a0b64c2c6795e) Signed-off-by:Minjae Kim <flowergom@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> (cherry picked from commit 6d0133c38fcb9b5ac3bdeaf65ef4d2cca2fc0586) Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.4 KiB
BlitzBasic
42 lines
1.4 KiB
BlitzBasic
SUMMARY = "gnu-configize"
|
|
DESCRIPTION = "Tool that installs the GNU config.guess / config.sub into a directory tree"
|
|
HOMEPAGE = "https://git.savannah.gnu.org/cgit/config.git"
|
|
SECTION = "devel"
|
|
LICENSE = "GPL-3.0-with-autoconf-exception"
|
|
LIC_FILES_CHKSUM = "file://config.guess;beginline=9;endline=29;md5=b75d42f59f706ea56d6a8e00216fca6a"
|
|
|
|
DEPENDS:class-native = "hostperl-runtime-native"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
SRCREV = "805517123cbfe33d17c989a18e78c5789fab0437"
|
|
PV = "20210722+git${SRCPV}"
|
|
|
|
SRC_URI = "git://git.savannah.gnu.org/git/config.git;protocol=https;branch=master \
|
|
file://gnu-configize.in"
|
|
S = "${WORKDIR}/git"
|
|
UPSTREAM_CHECK_COMMITS = "1"
|
|
|
|
CLEANBROKEN = "1"
|
|
|
|
do_compile[noexec] = "1"
|
|
|
|
do_install () {
|
|
install -d ${D}${datadir}/gnu-config \
|
|
${D}${bindir}
|
|
cat ${WORKDIR}/gnu-configize.in | \
|
|
sed -e 's,@gnu-configdir@,${datadir}/gnu-config,g' \
|
|
-e 's,@autom4te_perllibdir@,${datadir}/autoconf,g' > ${D}${bindir}/gnu-configize
|
|
# In the native case we want the system perl as perl-native can't have built yet
|
|
if [ "${PN}" != "gnu-config-native" -a "${PN}" != "nativesdk-gnu-config" ]; then
|
|
sed -i -e 's,/usr/bin/env,${bindir}/env,g' ${D}${bindir}/gnu-configize
|
|
fi
|
|
chmod 755 ${D}${bindir}/gnu-configize
|
|
install -m 0644 config.guess config.sub ${D}${datadir}/gnu-config/
|
|
}
|
|
|
|
PACKAGES = "${PN}"
|
|
FILES:${PN} = "${bindir} ${datadir}/gnu-config"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|