mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-01 13:58:04 +00:00
6f01d6ba0c
Error: Transaction test error: file /usr/include/luaconf.h conflicts between attempted installs of lua-dev-5.4.4-r0.aarch64 and lib32-lua-dev-5.4.4-r0.armv7ahf_neon The differences between the two files are as follows: @@ -219,7 +219,7 @@ #define LUA_ROOT "/usr/" #define LUA_LDIR LUA_ROOT "share/lua/" LUA_VDIR "/" -#define LUA_CDIR LUA_ROOT "lib64/lua/" LUA_VDIR "/" +#define LUA_CDIR LUA_ROOT "lib/lua/" LUA_VDIR "/" #if !defined(LUA_PATH_DEFAULT) #define LUA_PATH_DEFAULT \ (From OE-Core rev: b2892b3b6fa1d396f845539c0256ca0f71378b94) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit b58d86f9902a7eb7a821a3e36ba298c082c0f1f1) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
63 lines
2.3 KiB
BlitzBasic
63 lines
2.3 KiB
BlitzBasic
DESCRIPTION = "Lua is a powerful light-weight programming language designed \
|
|
for extending applications."
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://doc/readme.html;beginline=307;endline=330;md5=79c3f6b19ad05efe24c1681f025026bb"
|
|
HOMEPAGE = "http://www.lua.org/"
|
|
|
|
SRC_URI = "http://www.lua.org/ftp/lua-${PV}.tar.gz;name=tarballsrc \
|
|
file://lua.pc.in \
|
|
file://CVE-2022-28805.patch \
|
|
file://CVE-2022-33099.patch \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'ptest', 'http://www.lua.org/tests/lua-${PV_testsuites}-tests.tar.gz;name=tarballtest file://run-ptest ', '', d)} \
|
|
"
|
|
|
|
# if no test suite matches PV release of Lua exactly, download the suite for the closest Lua release.
|
|
PV_testsuites = "5.4.4"
|
|
|
|
SRC_URI[tarballsrc.sha256sum] = "164c7849653b80ae67bec4b7473b884bf5cc8d2dca05653475ec2ed27b9ebf61"
|
|
SRC_URI[tarballtest.sha256sum] = "04d28355cd67a2299dfe5708b55a0ff221ccb1a3907a3113cc103ccc05ac6aad"
|
|
|
|
inherit pkgconfig binconfig ptest
|
|
|
|
PACKAGECONFIG ??= "readline"
|
|
PACKAGECONFIG[readline] = ",,readline"
|
|
|
|
TARGET_CC_ARCH += " -fPIC ${LDFLAGS}"
|
|
EXTRA_OEMAKE = "'CC=${CC} -fPIC' 'MYCFLAGS=${CFLAGS} -fPIC' MYLDFLAGS='${LDFLAGS}' 'AR=ar rcD' 'RANLIB=ranlib -D'"
|
|
|
|
do_configure:prepend() {
|
|
sed -i -e s:/usr/local:${prefix}:g src/luaconf.h
|
|
sed -i -e s:lib/lua/:${baselib}/lua/:g src/luaconf.h
|
|
}
|
|
|
|
do_compile () {
|
|
oe_runmake ${@bb.utils.contains('PACKAGECONFIG', 'readline', 'linux-readline', 'linux', d)}
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake \
|
|
'INSTALL_TOP=${D}${prefix}' \
|
|
'INSTALL_BIN=${D}${bindir}' \
|
|
'INSTALL_INC=${D}${includedir}/' \
|
|
'INSTALL_MAN=${D}${mandir}/man1' \
|
|
'INSTALL_SHARE=${D}${datadir}/lua' \
|
|
'INSTALL_LIB=${D}${libdir}' \
|
|
'INSTALL_CMOD=${D}${libdir}/lua/5.4' \
|
|
install
|
|
install -d ${D}${libdir}/pkgconfig
|
|
|
|
sed -e s/@VERSION@/${PV}/ -e s#@LIBDIR@#${libdir}# -e s#@INCLUDEDIR@#${includedir}# ${WORKDIR}/lua.pc.in > ${WORKDIR}/lua.pc
|
|
install -m 0644 ${WORKDIR}/lua.pc ${D}${libdir}/pkgconfig/
|
|
rmdir ${D}${datadir}/lua/5.4
|
|
rmdir ${D}${datadir}/lua
|
|
}
|
|
|
|
do_install_ptest () {
|
|
cp -R --no-dereference --preserve=mode,links -v ${WORKDIR}/lua-${PV_testsuites}-tests ${D}${PTEST_PATH}/test
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
inherit multilib_script
|
|
MULTILIB_SCRIPTS = "${PN}-dev:${includedir}/luaconf.h"
|