mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-01 13:58:04 +00:00
4768cd6519
This sets a good example and avoids unnecessarily contributing to
perceived complexity and cargo culting.
Motivating quote below:
< kergoth> the *original* intent was for the function/task to error via
whatever appropriate means, bb.fatal, whatever, and
funcfailed was what you'd catch if you were calling
exec_func/exec_task. that is, it's what those functions
raise, not what metadata functions should be raising
< kergoth> it didn't end up being used that way
< kergoth> but there's really never a reason to raise it yourself
FuncFailed.__init__ takes a 'name' argument rather than a 'msg'
argument, which also shows that the original purpose got lost.
(From OE-Core rev: de45a7e302fe5a2a08baf26c91e2c788d7285263)
Signed-off-by: Ulf Magnusson <ulfalizer@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
67 lines
1.7 KiB
Plaintext
67 lines
1.7 KiB
Plaintext
addtask listtasks
|
|
do_listtasks[nostamp] = "1"
|
|
python do_listtasks() {
|
|
taskdescs = {}
|
|
maxlen = 0
|
|
for e in d.keys():
|
|
if d.getVarFlag(e, 'task', True):
|
|
maxlen = max(maxlen, len(e))
|
|
if e.endswith('_setscene'):
|
|
desc = "%s (setscene version)" % (d.getVarFlag(e[:-9], 'doc', True) or '')
|
|
else:
|
|
desc = d.getVarFlag(e, 'doc', True) or ''
|
|
taskdescs[e] = desc
|
|
|
|
tasks = sorted(taskdescs.keys())
|
|
for taskname in tasks:
|
|
bb.plain("%s %s" % (taskname.ljust(maxlen), taskdescs[taskname]))
|
|
}
|
|
|
|
CLEANFUNCS ?= ""
|
|
|
|
T_task-clean = "${LOG_DIR}/cleanlogs/${PN}"
|
|
addtask clean
|
|
do_clean[nostamp] = "1"
|
|
python do_clean() {
|
|
"""clear the build and temp directories"""
|
|
dir = d.expand("${WORKDIR}")
|
|
bb.note("Removing " + dir)
|
|
oe.path.remove(dir)
|
|
|
|
dir = "%s.*" % bb.data.expand(d.getVar('STAMP', False), d)
|
|
bb.note("Removing " + dir)
|
|
oe.path.remove(dir)
|
|
|
|
for f in (d.getVar('CLEANFUNCS', True) or '').split():
|
|
bb.build.exec_func(f, d)
|
|
}
|
|
|
|
addtask checkuri
|
|
do_checkuri[nostamp] = "1"
|
|
python do_checkuri() {
|
|
src_uri = (d.getVar('SRC_URI', True) or "").split()
|
|
if len(src_uri) == 0:
|
|
return
|
|
|
|
try:
|
|
fetcher = bb.fetch2.Fetch(src_uri, d)
|
|
fetcher.checkstatus()
|
|
except bb.fetch2.BBFetchException as e:
|
|
bb.fatal(str(e))
|
|
}
|
|
|
|
addtask checkuriall after do_checkuri
|
|
do_checkuriall[recrdeptask] = "do_checkuriall do_checkuri"
|
|
do_checkuriall[recideptask] = "do_${BB_DEFAULT_TASK}"
|
|
do_checkuriall[nostamp] = "1"
|
|
do_checkuriall() {
|
|
:
|
|
}
|
|
|
|
addtask fetchall after do_fetch
|
|
do_fetchall[recrdeptask] = "do_fetchall do_fetch"
|
|
do_fetchall[recideptask] = "do_${BB_DEFAULT_TASK}"
|
|
do_fetchall() {
|
|
:
|
|
}
|