mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-01 13:58:04 +00:00
fc351083e6
It is used in NVD for CVE's like: https://nvd.nist.gov/vuln/detail/CVE-2016-6153 (From OE-Core rev: c717da006b2f12c5ec4bcdc6bdbcb4d1098829a5) Signed-off-by: Mikko Rapeli <mikko.rapeli@bmw.de> Signed-off-by: Ross Burton <ross.burton@intel.com> (cherry picked from commit cec6f26f4d2f16c9a58fac5a6344e3d43b36ed09) Signed-off-by: Ruslan Ruslichenko <rruslich@cisco.com> Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
1.6 KiB
PHP
56 lines
1.6 KiB
PHP
SUMMARY = "Embeddable SQL database engine"
|
|
HOMEPAGE = "http://www.sqlite.org"
|
|
SECTION = "libs"
|
|
|
|
PE = "3"
|
|
|
|
def sqlite_download_version(d):
|
|
pvsplit = d.getVar('PV', True).split('.')
|
|
if len(pvsplit) < 4:
|
|
pvsplit.append('0')
|
|
return pvsplit[0] + ''.join([part.rjust(2,'0') for part in pvsplit[1:]])
|
|
|
|
SQLITE_PV = "${@sqlite_download_version(d)}"
|
|
|
|
S = "${WORKDIR}/sqlite-autoconf-${SQLITE_PV}"
|
|
|
|
UPSTREAM_CHECK_URI = "http://www.sqlite.org/"
|
|
UPSTREAM_CHECK_REGEX = "releaselog/(?P<pver>(\d+[\.\-_]*)+)\.html"
|
|
|
|
CVE_PRODUCT = "sqlite"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
PACKAGECONFIG ?= ""
|
|
PACKAGECONFIG_class-native = ""
|
|
|
|
PACKAGECONFIG[editline] = "--enable-editline,--disable-editline,libedit"
|
|
PACKAGECONFIG[readline] = "--enable-readline,--disable-readline,readline ncurses"
|
|
|
|
EXTRA_OECONF = " \
|
|
--enable-shared \
|
|
--enable-threadsafe \
|
|
--disable-static-shell \
|
|
"
|
|
|
|
# pread() is in POSIX.1-2001 so any reasonable system must surely support it
|
|
BUILD_CFLAGS += "-DUSE_PREAD"
|
|
TARGET_CFLAGS += "-DUSE_PREAD"
|
|
|
|
# Provide column meta-data API
|
|
BUILD_CFLAGS += "-DSQLITE_ENABLE_COLUMN_METADATA"
|
|
TARGET_CFLAGS += "-DSQLITE_ENABLE_COLUMN_METADATA"
|
|
|
|
PACKAGES = "lib${BPN} lib${BPN}-dev lib${BPN}-doc ${PN}-dbg lib${BPN}-staticdev ${PN}"
|
|
|
|
FILES_${PN} = "${bindir}/*"
|
|
FILES_lib${BPN} = "${libdir}/*.so.*"
|
|
FILES_lib${BPN}-dev = "${libdir}/*.la ${libdir}/*.so \
|
|
${libdir}/pkgconfig ${includedir}"
|
|
FILES_lib${BPN}-doc = "${docdir} ${mandir} ${infodir}"
|
|
FILES_lib${BPN}-staticdev = "${libdir}/lib*.a"
|
|
|
|
AUTO_LIBNAME_PKGS = "${MLPREFIX}lib${BPN}"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|