mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-01 13:58:04 +00:00
e417dce911
gettext has a notoriously slow configuration step, and so in my testing this greatly speeds up building core-image-minimal: from 21m36s to 19m2s (empty sstate and tmp, but pre-populated downloads). I have also built world, and core-image-sato to make sure it doesn't break or modify the build, and there is no difference whatsoever in packages and images content. Target gettext seems not to be used for anything. Also fix up insane.bbclass to remove the corresponding QA check. (From OE-Core rev: 1a7b843d575b290917d1e379c2ba106460988230) Signed-off-by: Alexander Kanavin <alexander.kanavin@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
25 lines
920 B
Plaintext
25 lines
920 B
Plaintext
def gettext_dependencies(d):
|
|
if d.getVar('INHIBIT_DEFAULT_DEPS') and not oe.utils.inherits(d, 'cross-canadian'):
|
|
return ""
|
|
if d.getVar('USE_NLS') == 'no':
|
|
return "gettext-minimal-native"
|
|
return d.getVar('DEPENDS_GETTEXT', False)
|
|
|
|
def gettext_oeconf(d):
|
|
if d.getVar('USE_NLS') == 'no':
|
|
return '--disable-nls'
|
|
# Remove the NLS bits if USE_NLS is no or INHIBIT_DEFAULT_DEPS is set
|
|
if d.getVar('INHIBIT_DEFAULT_DEPS') and not oe.utils.inherits(d, 'cross-canadian'):
|
|
return '--disable-nls'
|
|
return "--enable-nls"
|
|
|
|
DEPENDS_GETTEXT ??= "gettext-native"
|
|
|
|
BASEDEPENDS_append = " ${@gettext_dependencies(d)}"
|
|
EXTRA_OECONF_append = " ${@gettext_oeconf(d)}"
|
|
|
|
# Without this, msgfmt from gettext-native will not find ITS files
|
|
# provided by target recipes (for example, polkit.its).
|
|
GETTEXTDATADIRS_append_class-target = ":${STAGING_DATADIR}/gettext"
|
|
export GETTEXTDATADIRS
|