mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-01 13:58:04 +00:00
0dbbf3252f
The version 20250709 is the author date. * The changes are: a2287c3 Adjust 'time-stamp' variables to modern Emacs 973e3e6 config.sub: Add Tock OS support 3a71dc1 config.sub: recognize banan_os f91a544 config.sub: fix a duplicated case pattern 484648c config.sub: Include support for arm64_32 and iOS/tvOS/watchOS simulators 84cc2cc Update copyright years 7f41495 config.sub: add intelgt as a basic machine 9f6e0fe ironclad: change ironclad to ironclad-mlibc (From OE-Core rev: 28372102300a1c670a6a4fcea3f2f527c73aee56) Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.4 KiB
BlitzBasic
41 lines
1.4 KiB
BlitzBasic
SUMMARY = "gnu-configize"
|
|
DESCRIPTION = "Tool that installs the GNU config.guess / config.sub into a directory tree"
|
|
HOMEPAGE = "https://git.savannah.gnu.org/cgit/config.git"
|
|
SECTION = "devel"
|
|
LICENSE = "GPL-3.0-with-autoconf-exception"
|
|
LIC_FILES_CHKSUM = "file://config.guess;beginline=9;endline=29;md5=10922f9231863a06f6efb67691fa46e0"
|
|
|
|
DEPENDS:class-native = "hostperl-runtime-native"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
SRCREV = "a2287c3041a3f2a204eb942e09c015eab00dc7dd"
|
|
PV = "20250709+git"
|
|
|
|
SRC_URI = "git://git.savannah.gnu.org/git/config.git;protocol=https;branch=master \
|
|
file://gnu-configize.in"
|
|
UPSTREAM_CHECK_COMMITS = "1"
|
|
|
|
CLEANBROKEN = "1"
|
|
|
|
do_compile[noexec] = "1"
|
|
|
|
do_install () {
|
|
install -d ${D}${datadir}/gnu-config \
|
|
${D}${bindir}
|
|
cat ${UNPACKDIR}/gnu-configize.in | \
|
|
sed -e 's,@gnu-configdir@,${datadir}/gnu-config,g' \
|
|
-e 's,@autom4te_perllibdir@,${datadir}/autoconf,g' > ${D}${bindir}/gnu-configize
|
|
# In the native case we want the system perl as perl-native can't have built yet
|
|
if [ "${PN}" != "gnu-config-native" -a "${PN}" != "nativesdk-gnu-config" ]; then
|
|
sed -i -e 's,/usr/bin/env,${bindir}/env,g' ${D}${bindir}/gnu-configize
|
|
fi
|
|
chmod 755 ${D}${bindir}/gnu-configize
|
|
install -m 0644 config.guess config.sub ${D}${datadir}/gnu-config/
|
|
}
|
|
|
|
PACKAGES = "${PN}"
|
|
FILES:${PN} = "${bindir} ${datadir}/gnu-config"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|