mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-01 13:58:04 +00:00
33cffc4716
Backport patch [1] to fix CVE-2025-11731.
[1] fe508f201e
(From OE-Core rev: 7196077d84cc8d49652b0d6b54963df579ab1a0b)
Signed-off-by: Mingli Yu <mingli.yu@windriver.com>
Signed-off-by: Steve Sakoman <steve@sakoman.com>
71 lines
2.5 KiB
BlitzBasic
71 lines
2.5 KiB
BlitzBasic
SUMMARY = "GNOME XSLT library"
|
|
DESCRIPTION = "libxslt is the XSLT C parser and toolkit developed for the Gnome project. \
|
|
XSLT itself is a an XML language to define transformation for XML. Libxslt is based on \
|
|
libxml2 the XML C library developed for the GNOME project. It also implements most of \
|
|
the EXSLT set of processor-portable extensions functions and some of Saxon's evaluate \
|
|
and expressions extensions."
|
|
HOMEPAGE = "http://xmlsoft.org/XSLT/"
|
|
BUGTRACKER = "https://bugzilla.gnome.org/"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://Copyright;md5=0cd9a07afbeb24026c9b03aecfeba458"
|
|
|
|
SECTION = "libs"
|
|
DEPENDS = "libxml2"
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/libxslt/1.1/libxslt-${PV}.tar.xz \
|
|
file://CVE-2024-55549.patch \
|
|
file://CVE-2025-24855.patch \
|
|
file://CVE-2023-40403-001.patch \
|
|
file://CVE-2023-40403-002.patch \
|
|
file://CVE-2023-40403-003.patch \
|
|
file://CVE-2023-40403-004.patch \
|
|
file://CVE-2023-40403-005.patch \
|
|
file://CVE-2025-7424.patch \
|
|
file://CVE-2025-11731.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "8247f33e9a872c6ac859aa45018bc4c4d00b97e2feac9eebc10c93ce1f34dd79"
|
|
|
|
UPSTREAM_CHECK_REGEX = "libxslt-(?P<pver>\d+(\.\d+)+)\.tar"
|
|
|
|
# We have libxml2 2.9.14 and we don't link statically with it anyway
|
|
# so this isn't an issue.
|
|
CVE_CHECK_IGNORE += "CVE-2022-29824"
|
|
|
|
S = "${WORKDIR}/libxslt-${PV}"
|
|
|
|
BINCONFIG = "${bindir}/xslt-config"
|
|
|
|
inherit autotools pkgconfig binconfig-disabled lib_package multilib_header
|
|
|
|
do_configure:prepend () {
|
|
# We don't DEPEND on binutils for ansidecl.h so ensure we don't use the header.
|
|
# This can be removed when upgrading to 1.1.34.
|
|
sed -i -e 's/ansidecl.h//' ${S}/configure.ac
|
|
|
|
# The timestamps in the 1.1.28 tarball are messed up causing this file to
|
|
# appear out of date. Touch it so that we don't try to regenerate it.
|
|
touch ${S}/doc/xsltproc.1
|
|
}
|
|
|
|
EXTRA_OECONF = "--without-python --without-debug --without-mem-debug --without-crypto --with-html-subdir=${BPN}"
|
|
# older versions of this recipe had ${PN}-utils
|
|
RPROVIDES:${PN}-bin += "${PN}-utils"
|
|
RCONFLICTS:${PN}-bin += "${PN}-utils"
|
|
RREPLACES:${PN}-bin += "${PN}-utils"
|
|
|
|
# This is only needed until libxml can load the relocated catalog itself
|
|
do_install:append:class-native () {
|
|
create_wrapper ${D}/${bindir}/xsltproc XML_CATALOG_FILES=${sysconfdir}/xml/catalog
|
|
}
|
|
|
|
do_install:append () {
|
|
oe_multilib_header libxslt/xsltconfig.h
|
|
}
|
|
|
|
FILES:${PN} += "${libdir}/libxslt-plugins"
|
|
FILES:${PN}-dev += "${libdir}/xsltConf.sh"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|