mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-04 16:10:04 +00:00
edbf8d3999
There are issues with multilib due to the ordering of events where some functions see the remapped multilib dependencies and some do not. A significant problem is that the multilib class needs to make some changes before key expansion and some afterwards but by using existing event handlers, some code sees things in a partially translated state, leading to bugs. This patch changes things to use a new event handler from bitbake which makes the ordering of the changes explcit. The challenge in doing this is that it breaks some existing anonymous python and dyanmic assignments. In some cases these used to be translated and no longer are, meaning MLPREFIX has to be added. In some cases these are now translated and the MLPREFIX can be removed. This change does now make it very clear when MLPREFIX is required and when it is not, its just the migration path which is harder. The patch changes the small number of cases where fixes are needed. In particular, where a variable like RDEPENDS is conditionally extended (e.g. with an override), MLPREFIX is now required. This patch also reverts: base: Revert 'base.bbclass: considering multilib when setting LICENSE_EXCLUSION' This reverts 6597130256a1609c3e05ec5891aceaf549c37985 as the changes to multilib datastore handling mean its no longer necessary. (From OE-Core rev: b3fda056a674889cd9697e779de023d4f993d3ce) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
1.9 KiB
Plaintext
58 lines
1.9 KiB
Plaintext
#
|
|
# This class will generate the proper postinst/postrm scriptlets for font
|
|
# packages.
|
|
#
|
|
|
|
PACKAGE_WRITE_DEPS += "qemu-native"
|
|
inherit qemu
|
|
|
|
FONT_PACKAGES ??= "${PN}"
|
|
FONT_EXTRA_RDEPENDS ?= "${MLPREFIX}fontconfig-utils"
|
|
FONTCONFIG_CACHE_DIR ?= "${localstatedir}/cache/fontconfig"
|
|
FONTCONFIG_CACHE_PARAMS ?= "-v"
|
|
# You can change this to e.g. FC_DEBUG=16 to debug fc-cache issues,
|
|
# something has to be set, because qemuwrapper is using this variable after -E
|
|
# multiple variables aren't allowed because for qemu they are separated
|
|
# by comma and in -n "$D" case they should be separated by space
|
|
FONTCONFIG_CACHE_ENV ?= "FC_DEBUG=1"
|
|
fontcache_common() {
|
|
if [ -n "$D" ] ; then
|
|
$INTERCEPT_DIR/postinst_intercept update_font_cache ${PKG} mlprefix=${MLPREFIX} binprefix=${MLPREFIX} \
|
|
'bindir="${bindir}"' \
|
|
'libdir="${libdir}"' \
|
|
'libexecdir="${libexecdir}"' \
|
|
'base_libdir="${base_libdir}"' \
|
|
'fontconfigcachedir="${FONTCONFIG_CACHE_DIR}"' \
|
|
'fontconfigcacheparams="${FONTCONFIG_CACHE_PARAMS}"' \
|
|
'fontconfigcacheenv="${FONTCONFIG_CACHE_ENV}"'
|
|
else
|
|
${FONTCONFIG_CACHE_ENV} fc-cache ${FONTCONFIG_CACHE_PARAMS}
|
|
fi
|
|
}
|
|
|
|
python () {
|
|
font_pkgs = d.getVar('FONT_PACKAGES').split()
|
|
deps = d.getVar("FONT_EXTRA_RDEPENDS")
|
|
|
|
for pkg in font_pkgs:
|
|
if deps: d.appendVar('RDEPENDS_' + pkg, ' '+deps)
|
|
}
|
|
|
|
python add_fontcache_postinsts() {
|
|
for pkg in d.getVar('FONT_PACKAGES').split():
|
|
bb.note("adding fonts postinst and postrm scripts to %s" % pkg)
|
|
postinst = d.getVar('pkg_postinst_%s' % pkg) or d.getVar('pkg_postinst')
|
|
if not postinst:
|
|
postinst = '#!/bin/sh\n'
|
|
postinst += d.getVar('fontcache_common')
|
|
d.setVar('pkg_postinst_%s' % pkg, postinst)
|
|
|
|
postrm = d.getVar('pkg_postrm_%s' % pkg) or d.getVar('pkg_postrm')
|
|
if not postrm:
|
|
postrm = '#!/bin/sh\n'
|
|
postrm += d.getVar('fontcache_common')
|
|
d.setVar('pkg_postrm_%s' % pkg, postrm)
|
|
}
|
|
|
|
PACKAGEFUNCS =+ "add_fontcache_postinsts"
|