mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-04 16:10:04 +00:00
6a8b1d85e7
When newlib and libgloss were updated to 4.3.0, SRC_URI was updated to append a fix-rs6000-cflags.patch file when building on PowerPC, but this file was not added to the repo. Remove appending the missing patch. (From OE-Core rev: 71231580e9e5d0060a0ea41d29152d43846a00f1) Signed-off-by: Robert Joslyn <robert.joslyn@redrectangle.org> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 64561d8b81233a19df5f51d26dfbcd15835bec1f) Signed-off-by: Steve Sakoman <steve@sakoman.com>
36 lines
987 B
BlitzBasic
36 lines
987 B
BlitzBasic
require newlib.inc
|
|
|
|
DEPENDS += "newlib"
|
|
|
|
FILESEXTRAPATHS:prepend := "${THISDIR}/libgloss:"
|
|
|
|
SRC_URI:append = " file://libgloss-build-without-nostdinc.patch"
|
|
SRC_URI:append:powerpc = " file://fix-rs6000-crt0.patch"
|
|
|
|
do_configure() {
|
|
${S}/libgloss/configure ${EXTRA_OECONF}
|
|
}
|
|
|
|
do_install:prepend() {
|
|
# install doesn't create this itself, avoid install error
|
|
install -d ${D}${prefix}/${TARGET_SYS}/lib
|
|
}
|
|
|
|
do_install:append() {
|
|
# Move libs to default directories so they can be picked up later
|
|
install -d ${D}${libdir}
|
|
mv -v ${D}${prefix}/${TARGET_SYS}/lib/* ${D}${libdir}
|
|
|
|
# Remove original directory
|
|
rmdir -p --ignore-fail-on-non-empty ${D}${prefix}/${TARGET_SYS}/lib
|
|
}
|
|
|
|
# Split packages correctly
|
|
FILES:${PN} += "${libdir}/*.ld ${libdir}/*.specs"
|
|
FILES:${PN}-dev += "${libdir}/cpu-init/*"
|
|
# RiscV installation moved the syscall header to this location
|
|
FILES:${PN}-dev += "${prefix}/${TARGET_SYS}/include/machine/*.h"
|
|
|
|
INHIBIT_PACKAGE_STRIP = "1"
|
|
INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
|