mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-01 13:58:04 +00:00
76d0c749da
Changelog: https://github.com/libssh2/libssh2/releases/tag/libssh2-1.11.1 Dropped CVE-2023-48795.patch which is already included in version 1.11.1 Resolves: https://github.com/libssh2/libssh2/issues/1326 License-Update: Copyright symbols were changed from (C) to lowercase (c) ptest results: root@qemux86-64:~# ptest-runner libssh2 START: ptest-runner 2025-12-08T12:37 BEGIN: /usr/lib/libssh2/ptest PASS: mansyntax.sh PASS: test_simple PASS: test_sshd.test DURATION: 6 END: /usr/lib/libssh2/ptest 2025-12-08T12:37 STOP: ptest-runner TOTAL: 1 FAIL: 0 (From OE-Core rev: 71316433eb018e831d72a873365aa53ed04f14f4) Signed-off-by: Vijay Anusuri <vanusuri@mvista.com> Signed-off-by: Steve Sakoman <steve@sakoman.com>
53 lines
1.7 KiB
BlitzBasic
53 lines
1.7 KiB
BlitzBasic
SUMMARY = "A client-side C library implementing the SSH2 protocol"
|
|
HOMEPAGE = "http://www.libssh2.org/"
|
|
SECTION = "libs"
|
|
|
|
DEPENDS = "zlib"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2fbf8f834408079bf1fcbadb9814b1bc"
|
|
|
|
SRC_URI = "http://www.libssh2.org/download/${BP}.tar.gz \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "d9ec76cbe34db98eec3539fe2c899d26b0c837cb3eb466a56b0f109cabf658f7"
|
|
|
|
inherit autotools pkgconfig ptest
|
|
|
|
EXTRA_OECONF += "\
|
|
--with-libz \
|
|
--with-libz-prefix=${STAGING_LIBDIR} \
|
|
--disable-rpath \
|
|
"
|
|
DISABLE_STATIC = ""
|
|
|
|
# only one of openssl and gcrypt could be set
|
|
PACKAGECONFIG ??= "openssl"
|
|
PACKAGECONFIG[openssl] = "--with-crypto=openssl --with-libssl-prefix=${STAGING_LIBDIR}, , openssl"
|
|
PACKAGECONFIG[gcrypt] = "--with-crypto=libgcrypt --with-libgcrypt-prefix=${STAGING_EXECPREFIXDIR}, , libgcrypt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# required for ptest on documentation
|
|
RDEPENDS:${PN}-ptest = "bash man-db openssh util-linux-col"
|
|
RDEPENDS:${PN}-ptest:append:libc-glibc = " locale-base-en-us"
|
|
|
|
do_compile_ptest() {
|
|
sed -i "/\$(MAKE) \$(AM_MAKEFLAGS) check-TESTS/d" tests/Makefile
|
|
oe_runmake check
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
install -m 0755 ${S}/test-driver ${D}${PTEST_PATH}/
|
|
cp -rf ${B}/tests/.libs/* ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${B}/tests/test_simple ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/mansyntax.sh ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/key* ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/openssh_server/ ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/*.test ${D}${PTEST_PATH}/tests/
|
|
mkdir -p ${D}${PTEST_PATH}/docs
|
|
cp -r ${S}/docs/* ${D}${PTEST_PATH}/docs/
|
|
}
|