mirror of
https://git.yoctoproject.org/git/poky
synced 2026-01-01 13:58:04 +00:00
fe0287c81c
In an image recipe, you can get a warning, for example: WARNING: The postinstall intercept hook 'update_font_cache' failed (exit code: 1)! See log for details! WARNING: The postinstalls for the following packages will be postponed for first boot: ttf-dejavu-sans-mono (because /usr/bin/fc-cache is missing) In OE-core, rdepend is correctly done in each recipe: - ttf-fonts/liberation-fonts - ttf-fonts/ttf-bitstream-vera In meta-OE, rdepend is not done but packagegroup-fonts-truetype.bb includes fontconfig-utils: - ttf-fonts/ttf-arphic-uming - ttf-fonts/ttf-dejavu - ttf-fonts/ttf-droid - ttf-fonts/ttf-gentium - ttf-fonts/ttf-hunkyfonts - ttf-fonts/ttf-inconsolata - ttf-fonts/ttf-liberation - ttf-fonts/ttf-mplus - ttf-fonts/ttf-sazanami - ttf-fonts/ttf-ubuntu-font-family - ttf-fonts/ttf-wqy-zenhei (From OE-Core rev: 306335b13fedc18cf03da1c2a68e97c01eb59075) Signed-off-by: Matthieu Crapet <Matthieu.Crapet@ingenico.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.2 KiB
Plaintext
41 lines
1.2 KiB
Plaintext
#
|
|
# This class will generate the proper postinst/postrm scriptlets for font
|
|
# packages.
|
|
#
|
|
|
|
DEPENDS += "qemu-native"
|
|
inherit qemu
|
|
|
|
FONT_PACKAGES ??= "${PN}"
|
|
FONT_EXTRA_RDEPENDS ?= "fontconfig-utils"
|
|
|
|
fontcache_common() {
|
|
if [ "x$D" != "x" ] ; then
|
|
$INTERCEPT_DIR/postinst_intercept update_font_cache ${PKG} mlprefix=${MLPREFIX} bindir=${bindir} \
|
|
libdir=${libdir} base_libdir=${base_libdir}
|
|
else
|
|
fc-cache
|
|
fi
|
|
}
|
|
|
|
python populate_packages_append() {
|
|
font_pkgs = d.getVar('FONT_PACKAGES', True).split()
|
|
deps = d.getVar("FONT_EXTRA_RDEPENDS", True)
|
|
|
|
for pkg in font_pkgs:
|
|
if deps: d.appendVar('RDEPENDS_' + pkg, ' '+deps)
|
|
|
|
bb.note("adding fonts postinst and postrm scripts to %s" % pkg)
|
|
postinst = d.getVar('pkg_postinst_%s' % pkg, True) or d.getVar('pkg_postinst', True)
|
|
if not postinst:
|
|
postinst = '#!/bin/sh\n'
|
|
postinst += d.getVar('fontcache_common', True)
|
|
d.setVar('pkg_postinst_%s' % pkg, postinst)
|
|
|
|
postrm = d.getVar('pkg_postrm_%s' % pkg, True) or d.getVar('pkg_postrm', True)
|
|
if not postrm:
|
|
postrm = '#!/bin/sh\n'
|
|
postrm += d.getVar('fontcache_common', True)
|
|
d.setVar('pkg_postrm_%s' % pkg, postrm)
|
|
}
|